retrofit-graphql/build.gradle.kts at 99f429fc5e51a47c5c914f96f201b156833e247e · AniTrend/retrofit-graphql · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
import org.jetbrains.dokka.gradle.DokkaExtension

plugins {
    id("org.jetbrains.dokka")
}

buildscript {
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath(libs.android.gradle.plugin)
        classpath(libs.jetbrains.kotlin.gradle)
        classpath(libs.jetbrains.kotlin.serialization)
        classpath(libs.symbol.processing)
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
    }
}

// Multi-module Dokka: aggregate docs from all subprojects
dependencies {
    dokka(project(":annotations"))
    dokka(project(":api"))
    dokka(project(":android-assets"))
    dokka(project(":runtime"))
    dokka(project(":codegen-core"))
    dokka(project(":serialization-gson"))
    dokka(project(":serialization-kotlinx"))
    dokka(project(":library"))
}

dokka {
    dokkaPublications.html {
        outputDirectory.set(rootProject.file("dokka-docs"))
        failOnWarning.set(false)
    }
}

// Configure source links for subprojects that have Dokka applied
subprojects {
    plugins.withId("org.jetbrains.dokka") {
        extensions.configure(DokkaExtension::class.java) {
            val modulePath = project.path.removePrefix(":").replace(":", "/")

            dokkaSourceSets.configureEach {
                reportUndocumented.set(true)
                skipEmptyPackages.set(true)

                sourceLink {
                    localDirectory.set(layout.projectDirectory.dir("src/main/kotlin"))
                    remoteUrl.set(java.net.URI("https://github.com/AniTrend/retrofit-graphql/tree/develop/$modulePath/src/main/kotlin"))
                    remoteLineSuffix.set("#L")
                }
            }
        }
    }
}