Post/build.gradle.kts at main · MCCitiesNetwork/Post · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
plugins {
    java
    id("xyz.jpenilla.run-paper") version "3.0.2"
    id("com.gradleup.shadow") version "9.6.1"
}

group = "io.github.md5sha256"
version = "1.1.0-SNAPSHOT"

repositories {
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = uri("https://repo.papermc.io/repository/maven-public/")
    }
    maven {
        name = "sonatype"
        url = uri("https://oss.sonatype.org/content/groups/public/")
    }
    maven {
        name = "sonatype-snapshots"
        url = uri("https://oss.sonatype.org/content/repositories/snapshots/")
        mavenContent {
            snapshotsOnly()
        }
    }
    maven {
        name = "jitpack"
        url = uri("https://jitpack.io")
    }
    maven {
        name = "minebench-repo"
        url = uri("https://repo.minebench.de/")
        content {
            includeModule("de.themoep", "inventorygui")
        }
    }
    maven {
        name = "essentialsx"
        url = uri("https://repo.essentialsx.net/releases/")
        mavenContent {
            releasesOnly()
        }

    }
}

dependencies {
    compileOnly("io.papermc.paper:paper-api:1.21.8-R0.1-SNAPSHOT")
    compileOnly("com.arcaniax:HeadDatabase-API:1.3.2")
    compileOnly("com.github.MilkBowl:VaultAPI:1.7.1") {
        exclude(group = "org.bukkit", module = "bukkit")
        exclude(group = "org.spigotmc", module = "spigot-api")
        exclude(group = "io.papermc.paper", module = "paper-api")
    }
    compileOnly("net.essentialsx:EssentialsX:2.21.2") {
        exclude(group = "org.bukkit", module = "bukkit")
        exclude(group = "org.spigotmc", module = "spigot-api")
        exclude(group = "io.papermc.paper", module = "paper-api")
    }
    // Provided by spigot library
    compileOnly("org.mariadb.jdbc:mariadb-java-client:3.5.10")
    compileOnly("com.zaxxer:HikariCP:7.1.0")
    // Shaded libs
    implementation("de.themoep:inventorygui:1.6.1-SNAPSHOT")
    implementation("org.spongepowered:configurate-yaml:4.2.0")
    implementation("org.spongepowered:configurate-gson:4.2.0")
    implementation("org.incendo:cloud-paper:2.0.0") {
        exclude("com.google.guava")
    }
    implementation("org.incendo:cloud-processors-confirmation:1.0.0-rc.1") {
        exclude("com.google.guava")
    }
    implementation("org.incendo:cloud-annotations:2.1.0") {
        exclude("com.google.guava")
    }
    testImplementation(platform("org.junit:junit-bom:6.1.2"))
    testImplementation("org.junit.jupiter:junit-jupiter")
    testRuntimeOnly("org.junit.platform:junit-platform-launcher")
}

val targetJavaVersion = 21

java.toolchain.languageVersion.set(JavaLanguageVersion.of(targetJavaVersion))

tasks {

    withType(JavaCompile::class).configureEach {
        options.encoding = "UTF-8"
        options.release.set(targetJavaVersion)
    }

    test {
        useJUnitPlatform()
    }

    processResources {
        filesMatching("plugin.yml") {
            expand("version" to project.version)
        }
    }

    shadowJar {
        val path = "io.github.md5sha256.democracypost.libraries"
        relocate("org.incendo.cloud", "${path}.cloud")
        relocate("io.leangen.geantyref", "${path}.geantyref")
        relocate("org.spongepowered", "${path}.spongepowered")
        relocate("org.yaml.snakeyaml", "${path}.snakeyaml")
        relocate("com.google.gson", "${path}.gson")
        relocate("de.themoep.inventorygui", "${path}.inventorygui")
    }

    runServer {
        minecraftVersion("1.21.8")
        downloadPlugins {
            github("EssentialsX", "essentials", "2.21.2", "EssentialsX-2.21.2.jar")
            github("MilkBowl", "Vault", "1.7.3", "Vault.jar")
        }
    }
}