BetterBounty/build.gradle at master · Mirmir0lucky/BetterBounty · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
plugins {
    id 'java'
    id 'io.github.goooler.shadow' version "8.1.7"
}

group = 'dev.vireon'
version = '1.1.0'

repositories {
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
    maven {
        url "https://repo.triumphteam.dev/snapshots"
    }
    maven { url 'https://jitpack.io' }
    maven {
        name = "tcoded-releases"
        url = "https://repo.tcoded.com/releases"
    }
    maven {
        url = 'https://repo.extendedclip.com/releases/'
    }
}

dependencies {
    compileOnly('org.projectlombok:lombok:1.18.42')
    annotationProcessor 'org.projectlombok:lombok:1.18.42'

    implementation("dev.triumphteam:triumph-cmd-bukkit:2.0.0-SNAPSHOT") { exclude group: "com.google.code.gson" }
    implementation "dev.triumphteam:triumph-gui-paper:3.1.13-SNAPSHOT"

    implementation "de.rapha149.signgui:signgui:2.5.4"

    implementation "com.tcoded:FoliaLib:0.5.1"

    implementation "org.bstats:bstats-bukkit:3.1.0"

    compileOnly('com.github.MilkBowl:VaultAPI:1.7.1') {
        exclude group: 'org.bukkit'
    }

    compileOnly 'me.clip:placeholderapi:2.11.7'

    compileOnly("io.papermc.paper:paper-api:1.21.11-R0.1-SNAPSHOT")
}

def targetJavaVersion = 21
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'

    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release.set(targetJavaVersion)
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

shadowJar {
    dependsOn(jar)

    archiveFileName = "${project.name} v${archiveVersion.get()}.jar"

    relocate 'dev.triumphteam.gui', 'dev.vireon.bounty.libraries.gui'
    relocate 'dev.triumphteam.cmd', 'dev.vireon.bounty.libraries.cmd'
    relocate 'de.rapha149.signgui', 'dev.vireon.bounty.libraries.signgui'
    relocate 'com.tcoded.folialib', 'dev.vireon.bounty.libraries.folialib'
    relocate 'org.bstats', 'dev.vireon.bounty.libraries.bstats'

    from sourceSets.getByName("main").output
    configurations = [project.configurations.getByName("runtimeClasspath")]
}

build {
    dependsOn shadowJar
}