bm2011/pipedream.pov at master · Moomers/bm2011 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
// The PipeDream from BM 2010
//
// Pipes are 4 feet per square / 1.22 m --> define this to be 1
// pipe diameter 1.66 inches/ 4.2cm     --> this is 0.034

#include "colors.inc"
#include "metals.inc"
#include "glass.inc"
#include "stones1.inc"

camera {
  angle 70
  location <-3,-3.2,1>
  look_at <0,0,2>
  sky <0,0,1>
}

plane {
  <0,0,1>,0
  texture {T_Grnt15a}
}

// The vertical beams
#declare X = 0;
#while(X <= 5)
  #declare Y = 0;
  #while(Y <= 5)
    #declare Z=5;
    #if ((X =2) | (X=3))
      #declare Z=Z-1;
    #end
    #if ((Y =2) | (Y=3))
      #declare Z=Z-1;
    #end
    cylinder {
      <X,Y,0>,
      <X,Y,Z>,
      0.034
      texture {
        T_Chrome_3B
      }
    }
    #declare Y = Y+1;
  #end
  #declare X = X+1;
#end

// Lower Full Horizontal Beams
#declare X = 0;
#while(X <= 5)
  #declare Z = 0.5;
  #while(Z <= 2.5)
    cylinder {
      <X,0,Z>,
      <X,5,Z>,
      0.034
      texture {
        T_Chrome_3B
      }
    }
    #declare Z = Z+1;
  #end
  #declare X = X+1;
#end
// Lower Split Horizontal Beams
#declare X = 0;
#while(X <= 5)
  #declare Z = 3.5;
  #while(Z <= 4.5)
    #declare TMP = Z;
    #if ((X=2) | (X=3))
      #declare TMP=Z+1;
    #end
    #if (TMP < 5.5)
      cylinder {
        <X,0,Z>,
        <X,5.5-TMP,Z>,
        0.034
        texture {
          T_Chrome_3B
        }
      }
      cylinder {
        <X,5,Z>,
        <X,TMP-0.5,Z>,
        0.034
        texture {
          T_Chrome_3B
        }
      }
    #end

    #declare Z = Z+1;
  #end
  #declare X = X+1;
#end


// Higher Full Horizontal Beams
#declare Y = 0;
#while(Y <= 5)
  #declare Z = 1;
  #while(Z <= 3)
    cylinder {
      <0,Y,Z>,
      <5,Y,Z>,
      0.034
      texture {
        T_Chrome_3B
      }
    }
    #declare Z = Z+1;
  #end
  #declare Y = Y+1;
#end

// Higher Split Horizontal Beams
#declare Y = 0;
#while(Y <= 5)
  #declare Z = 4;
  #while(Z <= 5)
    #declare TMP = Z;
    #if ((Y=2) | (Y=3))
      #declare TMP=Z+1;
    #end
    #if (TMP < 6)
      cylinder {
        <0,Y,Z>,
        <6-TMP,Y,Z>,
        0.034
        texture {
          T_Chrome_3B
        }
      }
      cylinder {
        <5,Y,Z>,
        <TMP-1,Y,Z>,
        0.034
        texture {
          T_Chrome_3B
        }
      }
    #end

    #declare Z = Z+1;
  #end
  #declare Y = Y+1;
#end

#declare lantern = sphere {<0,0,0>,0.06 texture {T_Glass3}}

// Lights on the ground, outside the structure
//light_source { <-1, -1, 0> color White fade_distance 5 fade_power 1 looks_like {lantern}}
//light_source { <6, -1, 0> color White fade_distance 5 fade_power 1 looks_like {lantern}}
//light_source { <6, 6, 0> color White fade_distance 5 fade_power 1 looks_like {lantern}}
//light_source { <-1, 6, 0> color White fade_distance 5 fade_power 1 looks_like {lantern}}

// Lights in the towers
light_source { <0.5, 0.5, 5> color White fade_distance 3 fade_power 2 looks_like {lantern}}
light_source { <4.5, 0.5, 5> color White fade_distance 3 fade_power 2 looks_like {lantern}}
light_source { <4.5, 4.5, 5> color White fade_distance 3 fade_power 2 looks_like {lantern}}
light_source { <0.5, 4.5, 5> color White fade_distance 2 fade_power 2 looks_like {lantern}}


//light_source { <2.5, 2.5, 5.5> color White fade_distance 15 fade_power 1 looks_like {lantern}}
//light_source { <4.5, 1.5, 5.5> color White fade_distance 15 fade_power 1 looks_like {lantern}}
//light_source { <3.5, 2.5, 5.5> color White fade_distance 15 fade_power 1 looks_like {lantern}}
//light_source { <-3, -3, 1.2> color White fade_distance 15 fade_power 1 }