Wireless-Redstone/build.gradle at 1.20.1-master · MrTroble/Wireless-Redstone · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
plugins {
	id 'net.minecraftforge.gradle' version '6.0.+'
    id 'com.gradleup.shadow' version '9.2.0+'
	id 'eclipse'
	id 'net.darkhax.curseforgegradle' version '1.3.+'
	id "com.modrinth.minotaur" version "2.+"
}

group = project.mod_group
version = project.mod_version

base {
    archivesName = "${project.mod_name}-${project.minecraft_version}"
}

java {
    toolchain.languageVersion = JavaLanguageVersion.of(project.java_version.toInteger())
}

sourceSets{
    main {
        java {
            srcDirs("linkableapi/src/")
        }
    }
}

minecraft {
    mappings channel: 'official', version: project.minecraft_version

    runs {
        client {
            workingDirectory project.file('run')
            property 'forge.logging.console.level', 'debug'
        }

        server {
            property 'forge.logging.console.level', 'debug'
        }
    }
}

dependencies {
    minecraft "net.minecraftforge:forge:${project.minecraft_version}-${project.forge_version}"
}

jar {
    archiveClassifier.set("old")
}

shadowJar {
    archiveClassifier.set('')
    configurations = []
    relocate 'com.troblecodings.linkableapi', "${project.group}.tcredstone.shadow.linkableapi"

    manifest {
        attributes([
            "Specification-Title": project.mod_name,
            "Specification-Vendor": "troblecodings",
            "Specification-Version": project.version,
            "Implementation-Title": project.mod_name,
            "Implementation-Version": project.version,
            "Implementation-Vendor": "troblecodings",
            "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
        ])
    }

    from("changelog.md")
    from("LICENSE")
}

reobf {
    shadowJar {}
}

def releaseJar = file("$buildDir/libs/${project.mod_name}-${project.minecraft_version}-${project.mod_version}.jar")

tasks.register("publishCurseforge", net.darkhax.curseforgegradle.TaskPublishCurseForge) {
    dependsOn("reobfShadowJar")

    def key = System.getenv("CURSETOKEN")
    if (key == null)
        key = 'dev'
    apiToken = key

    def mainFile = upload(project.curseforge_project_id, releaseJar)
    mainFile.changelog = file("changelog.md").text
    mainFile.changelogType = 'markdown'
    mainFile.releaseType = 'release'
    mainFile.addModLoader("${project.loader}")
    mainFile.addEnvironment("Client", "Server")
    mainFile.addGameVersion("${project.minecraft_version}")
}

modrinth {
    token = System.getenv("MODRINTH_TOKEN")

    projectId = project.modrinth_project_id

    versionNumber = project.version
    versionName = "${project.mod_name} ${project.version}"

    uploadFile = releaseJar

    gameVersions = [project.minecraft_version]
    loaders = [project.loader.toLowerCase()]

    changelog = file("changelog.md").text
}

tasks.register("publishModrinth") {
    dependsOn("reobfShadowJar")
    dependsOn("modrinth")
}