Spritesheet export settings are not saved

[Schildkroet]

Pixelorama version:

1.1.10

Where did you download Pixelorama from?

Flatpak

OS/device including version:

Ubuntu 24.04

Issue description:

When exporting an image as spritesheet, it is possible to select different export options e.g. number of lines. But these settings are not saved in .pxo. Therefor i always have to edit them again (after closing and opening Pixelorama).
These settings should be saved, so export is consistent for all sessions and can be reproduced when sharing .pxo

[Qmaker-programmer]

cree el fork en mi cuenta, intentare agregar eso.... no se cuanto tardare, ¡con tantas issues pixelorama se pulira mas cada vez!

[Variable-ind]

Hello @Schildkroet @Qmaker-programmer I made this extension that stores the export settings in the project metadata whenever the export dialog is closed, and updates it according to current project's setting whenever the dialog i opened 😁.

Extension Download Link (Unzip it after download): PersistentExportOptions.pck.zip

Extension Code:

extends Node

@onready var extension_api: Node  ## A variable for easy reference to the Api


## This script acts as a setup for the extension
func _enter_tree() -> void:
	# NOTE: Use get_node_or_null("/root/ExtensionsApi") to access api.
	# NOTE: See https://www.oramainteractive.com/Pixelorama-Docs/extension_system/extension_api for
	# detailed documentation.
	extension_api = get_node_or_null("/root/ExtensionsApi")


	# |==== Your code goes here ====|
	var export_dialog = extension_api.general.get_global().export_dialog

	var old_connections: Array = export_dialog.about_to_popup.get_connections()
	for connection in old_connections:
		export_dialog.about_to_popup.disconnect(connection["callable"])
	export_dialog.about_to_popup.connect(deserialize_export_options)
	for connection in old_connections:
		export_dialog.about_to_popup.connect(connection["callable"])

	export_dialog.visibility_changed.connect(manage_sync)
	# |=============================|


func manage_sync():
	if not extension_api.general.get_global().export_dialog.visible:
		serialize_export_options()


func serialize_export_options():
	var export_autoload = extension_api.export.autoload()
	var data := {
		"current_tab": export_autoload.current_tab,
		"export_json": export_autoload.export_json,
		"split_layers": export_autoload.split_layers,
		"sheet_layers_as_separate_files": export_autoload.sheet_layers_as_separate_files,
		"crop_mode": export_autoload.crop_mode,
		"erase_unselected_area": export_autoload.erase_unselected_area,
		"orientation": export_autoload.orientation,
		"lines_count": export_autoload.lines_count,
		"frame_current_tag": export_autoload.frame_current_tag,
		"export_layers": export_autoload.export_layers,
		"number_of_frames": export_autoload.number_of_frames,
		"direction": export_autoload.direction,
		"repeat_count": export_autoload.repeat_count,
		"resize": export_autoload.resize,
		"save_quality": export_autoload.save_quality,
		"interpolation": export_autoload.interpolation,
		"include_tag_in_filename": export_autoload.include_tag_in_filename,
		"new_dir_for_each_frame_tag": export_autoload.new_dir_for_each_frame_tag,
		"number_of_digits": export_autoload.number_of_digits,
		"separator_character": export_autoload.separator_character
	}
	extension_api.project.current_project.set_meta("export_prefferences", data)


func deserialize_export_options():
	var export_autoload = extension_api.export.autoload()
	var export_data = extension_api.project.current_project.get_meta("export_prefferences", {})
	for property in export_data:
		export_autoload.set(property, export_data[property])


## Gets called when the extension is being disabled or uninstalled (while enabled).
func _exit_tree() -> void:
	# Remember to remove things that you added using this extension
	# Disconnect any signals and queue_free() any nodes that got added.
	extension_api.general.get_global().export_dialog.visibility_changed.disconnect(manage_sync)
	extension_api.general.get_global().export_dialog.about_to_popup.connect(deserialize_export_options)

[Qmaker-programmer]

Thanks, @Variable-ind. This will help me. Right now, I'm reading through part of Pixelorama and trying to understand the project itself (making notes on what each variable and function does so I don't break anything).