Save screenshots as PNGs

Author: Senryoku

src/deecy.zig

@@ -1926,7 +1926,7 @@ fn save_screenshot_impl(self: *const @This()) !void {
     const day_seconds = epoch_seconds.getDaySeconds();
     const year_day = epoch_seconds.getEpochDay().calculateYearDay();
     const month_day = year_day.calculateMonthDay();
-    const filepath = try std.fmt.allocPrint(self._allocator, "screenshots/{s}_{d:0>4}-{d:0>2}-{d:0>2}_{d:0>2}-{d:0>2}-{d:0>2}.bmp", .{
+    const filepath = try std.fmt.allocPrint(self._allocator, "screenshots/{s}_{d:0>4}-{d:0>2}-{d:0>2}_{d:0>2}-{d:0>2}-{d:0>2}.png", .{
         self.get_product_name(),
         year_day.year,
         month_day.month.numeric(),
@@ -1946,7 +1946,7 @@ fn save_screenshot_impl(self: *const @This()) !void {
 
     var buffer: [1024]u8 = undefined;
     var file_writer = file.writer(self.io, &buffer);
-    try screen.write_bmp(&file_writer.interface);
+    try screen.write_png(self._allocator, &file_writer.interface);
 
     deecy_log.info(termcolor.green("Screenshot saved as '{s}'"), .{filepath});
     self.ui.notifications.push("Screenshot Saved", .{}, "Screenshot saved as '{s}.", .{filepath});

src/image.zig

@@ -39,3 +39,74 @@ pub fn write_bmp(self: @This(), writer: *std.Io.Writer) !void {
 
     try writer.flush();
 }
+
+const PNGChunkWriter = struct {
+    writer: *std.Io.Writer,
+    crc: std.hash.Crc32 = .init(),
+
+    pub fn init(writer: *std.Io.Writer, data_length: u32, chunk_type: []const u8) !@This() {
+        try writer.writeInt(u32, data_length, .big);
+        var r = @This(){ .writer = writer };
+        std.debug.assert(chunk_type.len == 4);
+        try r.write(chunk_type);
+        return r;
+    }
+
+    pub fn writeInt(self: *@This(), val: u32) !void {
+        return self.write(std.mem.asBytes(&@byteSwap(val)));
+    }
+
+    pub fn write(self: *@This(), data: []const u8) !void {
+        try self.writer.writeAll(data);
+        self.crc.update(data);
+    }
+
+    pub fn finish(self: *@This()) !void {
+        try self.writer.writeInt(u32, self.crc.final(), .big);
+    }
+};
+
+pub fn write_png(self: @This(), allocator: std.mem.Allocator, writer: *std.Io.Writer) !void {
+    var alloc_writer = try std.Io.Writer.Allocating.initCapacity(allocator, self.bgra.len);
+    defer alloc_writer.deinit();
+    var compress_buffer: [std.compress.flate.max_window_len]u8 = undefined;
+    var compress = try std.compress.flate.Compress.init(&alloc_writer.writer, &compress_buffer, .zlib, .default);
+    for (0..self.height) |y| {
+        try compress.writer.writeByte(0); // Filter Type
+        for (0..self.width) |x| {
+            const bgra = self.bgra[y * self.width * 4 + 4 * x ..][0..4];
+            try compress.writer.writeAll(&[_]u8{ bgra[2], bgra[1], bgra[0] });
+        }
+    }
+    try compress.finish();
+
+    const compressed = try alloc_writer.toOwnedSlice();
+    defer allocator.free(compressed);
+
+    // PNG Signature
+    try writer.writeAll(&[_]u8{ 0x89, 0x50, 0x4E, 0x47, 0x0D, 0x0A, 0x1A, 0x0A });
+    {
+        var w = try PNGChunkWriter.init(writer, 13, "IHDR");
+        try w.writeInt(self.width);
+        try w.writeInt(self.height);
+        try w.write(&[_]u8{
+            8, // Bit-depth
+            2, // Color type (2: Truecolour)
+            0, // Compression Method
+            0, // Filter Method
+            0, // Interlace Method
+        });
+        try w.finish();
+    }
+    {
+        var w = try PNGChunkWriter.init(writer, @intCast(compressed.len), "IDAT");
+        try w.write(compressed);
+        try w.finish();
+    }
+    {
+        var w = try PNGChunkWriter.init(writer, 0, "IEND");
+        try w.finish();
+    }
+
+    try writer.flush();
+}