Meow_Meals/build.gradle.kts at main · Spacexplorer11/Meow_Meals · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
	id("net.fabricmc.fabric-loom-remap") version "1.16-SNAPSHOT"
	id("maven-publish")
	id("org.jetbrains.kotlin.jvm") version "2.3.0"
	id("me.modmuss50.mod-publish-plugin") version "0.8.4"
}

// These lines make the mod filename `{mod.id}-${mod.version}+${sc.current.version}.jar`
version = "${property("mod.version")}+${sc.current.version}"
base.archivesName = property("mod.id") as String
group = property("maven_group") as String

loom {
	splitEnvironmentSourceSets()

	mods {
		create("meowmeals") {
			sourceSet(sourceSets.getByName("main"))
			sourceSet(sourceSets.getByName("client"))
		}
	}

	runConfigs.all {
		runDir = "../../run"
		isIdeConfigGenerated = true
	}

}

fabricApi {
	configureDataGeneration {
		client = true
	}
}

dependencies {
	minecraft("com.mojang:minecraft:${sc.current.version}")
	mappings("net.fabricmc:yarn:${property("deps.yarn_mappings")}:v2")

	modImplementation("net.fabricmc:fabric-loader:${property("deps.fabric_loader")}")
	modImplementation("net.fabricmc.fabric-api:fabric-api:${property("deps.fabric_api")}")
	modImplementation("net.fabricmc:fabric-language-kotlin:${property("deps.fabric_kotlin")}")

	modCompileOnly("me.shedaniel:RoughlyEnoughItems-api-fabric:${property("deps.rei")}")
	modRuntimeOnly("me.shedaniel:RoughlyEnoughItems-fabric:${property("deps.rei")}")
}

tasks.withType<JavaCompile>().configureEach {
	options.release = 21
}

tasks.withType<KotlinCompile>().configureEach {
	compilerOptions {
		jvmTarget = JvmTarget.JVM_21
	}
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()
	sourceCompatibility = JavaVersion.VERSION_21
	targetCompatibility = JavaVersion.VERSION_21
}

tasks.named<Jar>("sourcesJar") {
	duplicatesStrategy = DuplicatesStrategy.INCLUDE
}

tasks.named<Jar>("jar") {
	duplicatesStrategy = DuplicatesStrategy.INCLUDE
	from("LICENSE") {
		rename { "${it}_${base.archivesName}" }
	}
}

tasks.named("processResources") {
	dependsOn(":${stonecutter.current.project}:stonecutterGenerate")
}

tasks.register<Copy>("buildAndCollect") {
	group = "build"
	duplicatesStrategy = DuplicatesStrategy.INCLUDE
	from(tasks.remapJar.map { it.archiveFile })
	into(rootProject.layout.buildDirectory.file("libs/${project.property("mod.version")}"))
	dependsOn("build")
}

tasks.named<ProcessResources>("processResources") {
	duplicatesStrategy = DuplicatesStrategy.INCLUDE
	inputs.property("minecraft_version", stonecutter.current.version)
	inputs.property("version", version)
	filesMatching("fabric.mod.json") {
		expand(
			mapOf(
				"minecraft_version" to stonecutter.current.version,
				"version" to version,
				"rei_version" to project.property("deps.rei"),
				"fabric_api_version" to project.property("deps.fabric_api"),
			)
		)
	}
}

publishMods {
	file = tasks.remapJar.map { it.archiveFile.get() }
	additionalFiles.from(tasks.named<Jar>("sourcesJar").map { it.archiveFile.get() })
	type = STABLE
	displayName = "Meow Meals v${property("mod.version")} for mc ${stonecutter.current.version}"
	version = "${property("mod.version")}+${stonecutter.current.version}"
	changelog = provider { rootProject.file("CHANGELOG.md").readText() }
	modLoaders.add("fabric")
	dryRun = false

	modrinth {
		projectId = "sVLmG6J3"
		accessToken = providers.environmentVariable("MODRINTH_API_KEY")
		minecraftVersions.add(stonecutter.current.version)
		requires("fabric-api")
		requires("fabric-language-kotlin")
		optional("rei")
	}
}