hpc-ops/CMakeLists.txt at main · Tencent/hpc-ops · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
cmake_minimum_required(VERSION 3.18)
project(hpc_ops LANGUAGES CXX CUDA)

enable_language(CUDA)
set(CMAKE_BUILD_TYPE "Release")

find_package(CUDAToolkit REQUIRED)
find_package(Python3 COMPONENTS Interpreter Development.Module REQUIRED)

file(GLOB_RECURSE SOURCES "src/*/*.cu" "src/*/*.cc")
file(GLOB CP_ASYNC_SOURCES "src/fuse_moe/cp_async/*.cu" "src/group_gemm/cp_async/*.cu"
                           "src/group_gemm/cp_async/*.cc")
list(APPEND SOURCES ${CP_ASYNC_SOURCES})
list(FILTER SOURCES EXCLUDE REGEX ".*test.*")


add_library(_C MODULE ${SOURCES})

set_target_properties(
  _C PROPERTIES
  LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/

  OUTPUT_NAME "_C"
  PREFIX ""
  SUFFIX ".abi3.so"
  CUDA_RUNTIME_LIBRARY "Shared"

  CUDA_SEPARABLE_COMPILATION OFF
  CUDA_RESOLVE_DEVICE_SYMBOLS ON
  SKIP_BUILD_RPATH TRUE

  C_VISIBILITY_PRESET "hidden"
  CXX_VISIBILITY_PRESET "hidden"
  VISIBILITY_INLINES_HIDDEN ON
  CUDA_VISIBILITY_PRESET "hidden"

  CXX_STANDARD 17
  CXX_STANDARD_REQUIRED ON
  CXX_EXTENSIONS OFF

  CUDA_STANDARD 17
  CUDA_STANDARD_REQUIRED ON
  CUDA_EXTENSIONS OFF

  CUDA_ARCHITECTURES "90a"
)

target_compile_definitions(
  _C PRIVATE
  Py_LIMITED_API=0x03090000
  _GLIBCXX_USE_CXX11_ABI=1
  HPC_GIT_HASH_STR=${HPC_GIT_HASH_STR}
  HPC_VERSION_STR=${HPC_VERSION_STR}
)

execute_process(
  COMMAND python3 -c "
from torch.utils.cpp_extension import include_paths
print(';'.join(include_paths()), end='')
"
  OUTPUT_VARIABLE TORCH_INCLUDE_PATHS
)

execute_process(
  COMMAND python3 -c "
from torch.utils.cpp_extension import library_paths
print(';'.join(library_paths()), end='')
"
  OUTPUT_VARIABLE TORCH_LIBRARY_PATHS
)


target_include_directories(
  _C PRIVATE
  ./
  3rd/cutlass/include
  ${CUDAToolkit_INCLUDE_DIRS}
  ${TORCH_INCLUDE_PATHS}
)

target_link_directories(
  _C PRIVATE
  ${TORCH_LIBRARY_PATHS}
)

target_link_libraries(
  _C PRIVATE
  cuda
  c10
  torch
  torch_cpu
  cudart
  c10_cuda
  torch_cuda
)

target_compile_options(
  _C PRIVATE
  $<$<COMPILE_LANGUAGE:CUDA>:
    -Werror=all-warnings
    -lineinfo
    --expt-relaxed-constexpr
    -std=c++17
    -DCUTE_SM90_EXTENDED_MMA_SHAPES_ENABLED
    -DNDEBUG
    -Xptxas=-warn-double-usage,-v
  >
  $<$<COMPILE_LANGUAGE:CXX>:
    -Wno-unused-result
    -Wsign-compare
    -g
    -fwrapv
    -Wall
    -DTORCH_API_INCLUDE_EXTENSION_H
    -DTORCH_EXTENSION_NAME=_C
  >
)