build.gradle

plugins {
    id "io.freefair.lombok" version "8.13"
    id 'com.matthewprenger.cursegradle' version '1.4.0'
    id 'org.ajoberstar.grgit' version '5.2.2'
    id 'net.neoforged.gradle.userdev' version '7.1.25'
}

apply plugin: 'maven-publish'
apply plugin: 'eclipse'

boolean dev = System.getenv('RELEASE') == null || System.getenv('RELEASE').equals('false')
def getVersion = {
    def raw = grgit.describe(commit: 'HEAD', longDescr: true, tags: true)
    def desc = (raw == null ? '0.0-0-unknown' : grgit.describe(commit: 'HEAD', longDescr: true, tags: true)).split('-') as List
    System.out.println(desc)
    def hash = desc.remove(desc.size() - 1).substring(1)
    def offset = desc.remove(desc.size() - 1)
    return project.mod_version.replace('x', offset) + (System.getenv("GITHUB_RUN_NUMBER") == null ? "+${hash}" : "")
}

System.out.println(JavaVersion.current())

version = "MC${release_minecraft_version}-${getVersion()}"
group = "com.tterrag.registrate"
base.archivesName = "Registrate"

java.toolchain.languageVersion = JavaLanguageVersion.of(25)

runs {
    configureEach {
        systemProperty 'forge.logging.markers', 'REGISTRIES,REGISTRYDUMP'
        systemProperty 'forge.logging.console.level', 'debug'

        modSource project.sourceSets.test
        modSource project.sourceSets.main

        idea {
            primarySourceSet = project.sourceSets.test
        }
    }

    client {
        workingDirectory project.file('run')
        systemProperty 'neoforge.enabledGameTestNamespaces', 'testmod'
    }

    server {
        workingDirectory project.file('run/server')
        arguments '--nogui'
        systemProperty 'neoforge.enabledGameTestNamespaces', 'testmod'
    }

    gameTestServer {
        systemProperty 'neoforge.enabledGameTestNamespaces', 'testmod'
    }

    clientData {
        workingDirectory project.file('run')

        arguments.addAll '--mod', 'testmod', '--all', '--output', rootProject.file('src/generated/resources/').getAbsolutePath(), '--existing', rootProject.file('src/test/resources').getAbsolutePath()
    }
}

sourceSets.main.resources {
    srcDir 'src/generated/resources'
}

repositories {
    maven {
        name = 'tterrag'
        url = 'https://maven.tterrag.com/'
    }
}

dependencies {
    implementation "net.neoforged:neoforge:${neo_version}"
    implementation "net.neoforged:testframework:${neo_version}"

    implementation "javax.annotation:javax.annotation-api:1.3.2"

    testImplementation "org.junit.jupiter:junit-jupiter-api:5.7.2"
    testRuntimeOnly    "org.junit.jupiter:junit-jupiter-engine:5.7.2"
}

test {
    failOnNoDiscoveredTests = false
}

lombok {
    version = "1.18.44"
}

delombok {
    format = [
        'suppressWarnings': 'skip',
        'javaLangAsFQN': 'skip'
    ]
}

jar {
    exclude('assets/**', 'data/**', '.cache/**') // Exclude generated assets, can't find a better way to do this :(
    manifest {
        attributes(
            'FMLModType': 'GAMELIBRARY'
        )
    }
}

tasks.register('sourceJar', Jar) {
    dependsOn classes
    archiveClassifier = 'sources'
    from sourceSets.main.delombokTask
    exclude 'com.tterrag.registrate.test.*'
}

javadoc {
    source = delombok
    configure (options) {
        tags(
           'apiNote:a:API Note:',
           'implNote:a:Implementation Note:'
        )
    }
}

publishing {
    tasks.publish.dependsOn 'build'
    tasks.publishToMavenLocal.dependsOn 'build'
    publications {
        mavenJava(MavenPublication) {
            artifact jar
            artifact sourceJar
        }
    }

    repositories {
        if (project.hasProperty('mavendir')) {
            maven { url mavendir }
        }

        def mavenToken = System.getenv("MAVEN_TOKEN")
        if (mavenToken != null && !mavenToken.isEmpty()) {
            maven {
                url = "https://maven.gegy.dev/releases"
                credentials {
                    username = "registrate"
                    password = mavenToken
                }
            }
        }
    }
}

repositories {
    maven {
        url 'https://repo.maven.apache.org/maven2'
        name 'Maven Central'
    }
}