DependencyTreeForm.pas

{-------------------------------------------------------------------------------

  This Source Code Form is subject to the terms of the Mozilla Public
  License, v. 2.0. If a copy of the MPL was not distributed with this
  file, You can obtain one at http://mozilla.org/MPL/2.0/.

-------------------------------------------------------------------------------}
unit DependencyTreeForm;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, StdCtrls, ExtCtrls,
  DependencyFrame,
  DepsTracker_Project, Menus;

type
  TfDependencyTreeForm = class(TForm)
    cbFullNames: TCheckBox;
    trvDepsTree: TTreeView;
    pmTreeControl: TPopupMenu;
    pmiTree_Expand: TMenuItem;
    pmiTree_Collapse: TMenuItem;
    gbSelectedNode: TGroupBox;
    scbDependencies: TScrollBox;
    bvlChainSeparator: TBevel;
    btnShowAllCondNotes: TButton;
    procedure cbFullNamesClick(Sender: TObject);
    procedure trvDepsTreeChange(Sender: TObject; Node: TTreeNode);
    procedure pmTreeControlPopup(Sender: TObject);
    procedure pmiTree_ExpandClick(Sender: TObject);
    procedure pmiTree_CollapseClick(Sender: TObject);
    procedure btnShowAllCondNotesClick(Sender: TObject);  
  private
    { Private declarations }
  protected
    fProject:       TDTPRoject;
    fSelectedNode:  TTreeNode;
    fDepsTable:     array of record
                      Dependent:  TDTProject;
                      Dependency: TDTProject;
                      Frame:      TfrmDependencyFrame;
                    end;
    procedure ConstructTree;
    procedure RenameTree;
    procedure SetSelectedNode(Node: TTreeNode);
  public
    { Public declarations }
    procedure Explore(Project: TDTProject);
  end;

var
  fDependencyTreeForm: TfDependencyTreeForm;

implementation

uses TextEditForm;

{$R *.dfm}

procedure TfDependencyTreeForm.Explore(Project: TDTProject);
begin
If Assigned(Project) then
  begin
    fProject := Project;
    Caption := Project.Name + ' - Dependency tree';    
    ConstructTree;
    ShowModal;
  end;
end;

//------------------------------------------------------------------------------

procedure TfDependencyTreeForm.ConstructTree;

  procedure AddSubNodes(Node: TTreeNode; Project: TDTProject);
  var
    i:        Integer;
    TempNode: TTreeNode;
  begin
    For i := Project.DependenciesLowIndex to Project.DependenciesHighIndex do
      begin
        // add the node with placeholder name
        TempNode := trvDepsTree.Items.AddChildObject(Node,Project.Dependencies[i].Name,Project.Dependencies[i]);
        // recursively add subnodes
        If Project.Dependencies[i].BeginInterlockedOperations then
          try
            AddSubNodes(TempNode,Project.Dependencies[i]);
          finally
            Project.Dependencies[i].EndInterlockedOperations;
          end;
      end;
  end;

var
  TempNode: TTreeNode;
begin
trvDepsTree.Items.BeginUpdate;
try
  trvDepsTree.Items.Clear;
  If cbFullNames.Checked then
    TempNode := trvDepsTree.Items.AddChildObject(nil,fProject.FullName,fProject)
  else
    TempNode := trvDepsTree.Items.AddChildObject(nil,fProject.Name,fProject);
  If fProject.BeginInterlockedOperations then
    try
      AddSubNodes(TempNode,fProject);
    finally
      fProject.EndInterlockedOperations;
    end;
  RenameTree;
  TempNode.Expand(False);
  trvDepsTree.Selected := TempNode;
finally
  trvDepsTree.Items.EndUpdate;
end;
end;

//------------------------------------------------------------------------------

procedure TfDependencyTreeForm.RenameTree;

  procedure RenameSubNodes(Node: TTreeNode);
  var
    Project:    TDTProject;
    UncondOnly: Boolean;
    i:          Integer;
    TempName:   String;
  begin
    If Node.Count > 0 then
      begin
        Project := TDTProject(Node.Data);
        UncondOnly := True;
        For i := Project.DependenciesLowIndex to Project.DependenciesHighIndex do
          If Project.DependenciesInfo[i].Conditional then
            begin
              UncondOnly := False;
              Break{For i};
            end;
        For i := Project.DependenciesLowIndex to Project.DependenciesHighIndex do
          begin
            // prepare node name
            If cbFullNames.Checked then
              TempName := Project.Dependencies[i].FullName
            else
              TempName := Project.Dependencies[i].Name;
            // rename the node with rectified name
            If not UncondOnly then
              begin
              If Project.DependenciesInfo[i].Conditional then
                Node.Item[i].Text := '* ' + TempName
              else
                Node.Item[i].Text := '  ' + TempName
              end
            else Node.Item[i].Text := TempName;
            // recursively rename subnodes
            RenameSubNodes(Node.Item[i]);
            If (Node.Item[i].Count <= 0) and (Project.Dependencies[i].DependenciesCount > 0) then
              Node.Item[i].Text := Node.Item[i].Text + ' (...)';
          end;
      end;
  end;

var
  Root: TTreeNode;
  i:    Integer;
begin
trvDepsTree.Items.BeginUpdate;
try
  // find root node
  Root := nil;
  For i := 0 to Pred(trvDepsTree.Items.Count) do
    If not Assigned(trvDepsTree.Items[i].Parent) then
      begin
        Root := trvDepsTree.Items[i];
        Break{For i};
      end;
  If Assigned(Root) then
    begin
      // rename root
      If cbFullNames.Checked then
        Root.Text := TDTProject(Root.Data).FullName
      else
        Root.Text := TDTProject(Root.Data).Name;
      // recursively traverse tree and rename the nodes
      RenameSubNodes(Root);
    end;
finally
  trvDepsTree.Items.EndUpdate;
end;
end;

//------------------------------------------------------------------------------

procedure TfDependencyTreeForm.SetSelectedNode(Node: TTreeNode);
var
  i:        Integer;
  TempNode: TTreeNode;
  Enable:   Boolean;
begin
If Node <> fSelectedNode then
  begin
    For i := Low(fDepsTable) to High(fDepsTable) do
      FreeAndNil(fDepsTable[i].Frame);
    fSelectedNode := Node;
    If Assigned(fSelectedNode) then
      begin
        SetLength(fDepsTable,Node.Level);
        TempNode := Node;
        Enable := False;
        For i := High(fDepsTable) downto Low(fDepsTable) do
          begin
            fDepsTable[i].Dependency := TDTProject(TempNode.Data);
            fDepsTable[i].Dependent := TDTProject(TempNode.Parent.Data);
            // create, place and size frame
            fDepsTable[i].Frame := TfrmDependencyFrame.Create(Self);
            fDepsTable[i].Frame.Parent := scbDependencies;
            fDepsTable[i].Frame.Name := Format('%s_%d',[fDepsTable[i].Frame.Name,i]);
            fDepsTable[i].Frame.Left := 0;
            If i <= Low(fDepsTable) then
              fDepsTable[i].Frame.Top := 0
            else
              fDepsTable[i].Frame.Top := (i * (fDepsTable[i].Frame.Height + 8));
            If fDepsTable[i].Frame.Fill(fDepsTable[i].Dependent,fDepsTable[i].Dependency,TempNode.Count <= 0) then
              Enable := True;
            If scbDependencies.VertScrollBar.IsScrollBarVisible then
              fDepsTable[i].Frame.Width := scbDependencies.ClientWidth - 6
            else
              fDepsTable[i].Frame.Width := scbDependencies.ClientWidth;
            // new round...
            TempNode := TempNode.Parent;
          end;  
        If Length(fDepsTable) > 0 then
          begin
            scbDependencies.ScrollInView(fDepsTable[High(fDepsTable)].Frame);
            scbDependencies.Visible := True;
            btnShowAllCondNotes.Enabled := Enable;
          end
        else
          begin
            scbDependencies.Visible := False;
            btnShowAllCondNotes.Enabled := False;
          end;
      end
    else
      begin
        SetLength(fDepsTable,0);
        scbDependencies.Visible := False;
        btnShowAllCondNotes.Enabled := False;
      end;
  end;
end;

//==============================================================================

procedure TfDependencyTreeForm.cbFullNamesClick(Sender: TObject);
begin
RenameTree;
end;

//------------------------------------------------------------------------------

procedure TfDependencyTreeForm.trvDepsTreeChange(Sender: TObject; Node: TTreeNode);
begin
SetSelectedNode(Node);
end;

//------------------------------------------------------------------------------

procedure TfDependencyTreeForm.pmTreeControlPopup(Sender: TObject);
var
  MousePoint:  TPoint;
  Node: TTreeNode;
begin
MousePoint := trvDepsTree.ScreenToClient(Point(Mouse.CursorPos.X,Mouse.CursorPos.Y));
Node := trvDepsTree.GetNodeAt(MousePoint.Y,MousePoint.Y);
If Assigned(Node) then
  trvDepsTree.Selected := Node;
end;

//------------------------------------------------------------------------------

procedure TfDependencyTreeForm.pmiTree_ExpandClick(Sender: TObject);
begin
If Assigned(trvDepsTree.Selected) then
  trvDepsTree.Selected.Expand(True);
end;

//------------------------------------------------------------------------------

procedure TfDependencyTreeForm.pmiTree_CollapseClick(Sender: TObject);
begin
If Assigned(trvDepsTree.Selected) then
  trvDepsTree.Selected.Collapse(True);
end;

//------------------------------------------------------------------------------

procedure TfDependencyTreeForm.btnShowAllCondNotesClick(Sender: TObject);
var
  Lines:    TStringList;
  i,Index:  Integer;
begin
If Assigned(fSelectedNode) then
  begin
    Lines := TStringList.Create;
    try
      For i := Low(fDepsTable) to High(fDepsTable) do
        If fDepsTable[i].Dependent.DependenciesFind(fDepsTable[i].Dependency,Index) then
          If Length(fDepsTable[i].Dependent.DependenciesInfo[Index].ConditionNotes) > 0 then
            begin
              If Lines.Count > 0 then
                Lines.Add(sLineBreak);  // twoempty lines
              Lines.Add(Format('%s - %s',[fDepsTable[i].Dependent.Name,fDepsTable[i].Dependency.Name]));
              Lines.Add('');
              Lines.Add(fDepsTable[i].Dependent.DependenciesInfo[Index].ConditionNotes);
            end;
      fTextEditForm.ShowTextReadOnly(
        Format('%s - all condition notes',[TDTProject(fSelectedNode.Data).Name]),
        Lines.Text,False);
    finally
      Lines.Free;
    end;
  end;
end;

end.