nix-dotfiles/flake.nix at main · Wittano/nix-dotfiles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
{
  description = "Wittano NixOS configuration";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-26.05";
    expert-ls.url = "github:elixir-lang/expert";
    nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";
    nixpkgs-master.url = "github:NixOS/nixpkgs/master";
    determinate = {
      url = "https://flakehub.com/f/DeterminateSystems/determinate/*";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    home-manager = {
      url = "github:nix-community/home-manager/release-26.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    filebot.url = "github:Wittano/filebot";
    aagl = {
      url = "github:ezKEa/aagl-gtk-on-nix/release-26.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixvim = {
      url = "github:nix-community/nixvim/nixos-26.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    honkai-railway-grub-theme.url = "github:voidlhf/StarRailGrubThemes";
    catppuccin = {
      url = "github:catppuccin/nix/release-26.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    catppuccin-dunst = {
      url = "github:catppuccin/dunst";
      flake = false;
    };
    xmonad-contrib.url = "github:xmonad/xmonad-contrib";
    agenix = {
      url = "github:ryantm/agenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nix-index-database = {
      url = "github:nix-community/nix-index-database";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixos-hardware = {
      url = "github:NixOS/nixos-hardware";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      home-manager,
      ...
    }@inputs:
    let
      system = "x86_64-linux";

      mkPkgs =
        p:
        import p {
          inherit system;

          config.allowUnfree = true;
          overlays = import ./overlays.nix {
            inherit lib;
            pkgs = p;
          };
        };

      pkgs = mkPkgs inputs.nixpkgs;
      unstable = mkPkgs inputs.nixpkgs-unstable;
      master = mkPkgs inputs.nixpkgs-master;

      lib = nixpkgs.lib.extend (
        sefl: super: {
          inherit (home-manager.lib) hm;

          my = import ./lib {
            inherit
              lib
              pkgs
              system
              inputs
              unstable
              master
              ;
          };
        }
      );
    in
    {
      lib = lib.my;

      nixosConfigurations = {
        pc-xmonad = lib.my.hosts.mkHost "pc" "xmonad";
        pc-openbox = lib.my.hosts.mkHost "pc" "openbox";
        pc-qtile = lib.my.hosts.mkHost "pc" "qtile";
        pc-labwc = lib.my.hosts.mkHost "pc" "labwc";
        pc-bspwm = lib.my.hosts.mkHost "pc" "bspwm";

        framework-xmonad = lib.my.hosts.mkHost "framework" "xmonad";
        framework-openbox = lib.my.hosts.mkHost "framework" "openbox";
        framework-qtile = lib.my.hosts.mkHost "framework" "qtile";
        framework-labwc = lib.my.hosts.mkHost "framework" "labwc";
        framework-bspwm = lib.my.hosts.mkHost "framework" "bspwm";
      };
      devShells.${system}.default = unstable.callPackage ./shell.nix { };
      templates = import ./templates.nix { inherit lib; };
    };
}