OxiRun/flake.nix at main · Xetibo/OxiRun · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
{
  description = "A simple application runner made with Iced";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-parts = {
      url = "github:hercules-ci/flake-parts";
      inputs.nixpkgs-lib.follows = "nixpkgs";
    };
  };

  outputs = inputs @ {
    self,
    flake-parts,
    ...
  }:
    flake-parts.lib.mkFlake {inherit inputs;} {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      perSystem = {
        self',
        pkgs,
        system,
        ...
      }: {
        _module.args.pkgs = import self.inputs.nixpkgs {
          inherit system;
        };
        devShells.default = let
          libPath = with pkgs;
            lib.makeLibraryPath [
              libGL
              libxkbcommon
              wayland
              pkg-config
              libclang
              vulkan-loader
              mesa
            ];
          driverIcdPath = "${pkgs.mesa}/share/vulkan/icd.d";
          icdArch =
            if system == "x86_64-linux"
            then "x86_64"
            else if system == "aarch64-linux"
            then "aarch64"
            else "x86_64";
        in
          pkgs.mkShell {
            inputsFrom = builtins.attrValues self'.packages;
            packages = with pkgs; [
              cargo
              cargo-watch
              rustc
              rust-analyzer
              clippy
              rustfmt
            ];
            LD_LIBRARY_PATH = libPath;
            LIBCLANG_PATH = "${pkgs.libclang.lib}/lib";
            VK_ICD_FILENAMES = "${driverIcdPath}/radeon_icd.${icdArch}.json:${driverIcdPath}/intel_icd.${icdArch}.json";
          };

        packages = let
          lockFile = ./oxirun/Cargo.lock;
        in rec {
          oxirun = pkgs.callPackage ./nix/default.nix {inherit inputs lockFile;};
          oxirun-applications = pkgs.callPackage ./nix/applications.nix {inherit inputs;};
          # TODO check if this can be improved to immediately use plugins as well?
          default = oxirun;
        };
      };
      flake = _: rec {
        nixosModules.home-manager = homeManagerModules.default;
        homeManagerModules = rec {
          oxirun = import ./nix/hm.nix inputs.self;
          default = oxirun;
        };
      };
    };
}