melonDS-X432R-Plus/src/OpenGL_shaders/3DTexcacheRepackFS.glsl at x432r-plus · ZironZ/melonDS-X432R-Plus · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
// Copyright 2026 ZironZ
// SPDX-License-Identifier: GPL-3.0-or-later

#version 140

uniform sampler2D Source;
uniform int uOutputFormat;
uniform int uBinaryAlpha;
uniform int uPreserveTransparentRGB;
uniform int uRGB6RepackPolicy;

smooth in vec2 fTexcoord;
#ifdef FILTERABLE_TEXTURE_CACHE
out vec4 oColor;
#else
out uvec4 oColor;
#endif

uint QuantizeRGB8ToRGB6LikeDS(float value)
{
    value = clamp(value, 0.0, 255.0);
    int value5 = clamp(int(floor((value / 8.0) + 0.5)), 0, 31);
    if (value5 == 0)
        return 0u;
    return uint(value5 * 2 + 1);
}

uint QuantizeRGB8ToRGB6Roundtrip(float value)
{
    value = clamp(value, 0.0, 255.0);
    return uint(clamp(floor(value * (63.0 / 255.0) + 0.5), 0.0, 63.0));
}

uint QuantizeRGB8ToRGB6(float value)
{
    return uRGB6RepackPolicy == 1
        ? QuantizeRGB8ToRGB6Roundtrip(value)
        : QuantizeRGB8ToRGB6LikeDS(value);
}

uint QuantizeChannel(float value, float maxValue)
{
    return uint(clamp(floor(value * maxValue + 0.5), 0.0, maxValue));
}

void main()
{
    vec4 color = texture(Source, fTexcoord);

    if (uBinaryAlpha != 0)
    {
        color.a = color.a >= 0.5 ? 1.0 : 0.0;
        if (color.a == 0.0 && uPreserveTransparentRGB == 0)
            color.rgb = vec3(0.0);
    }

    if (uOutputFormat == 0)
    {
#ifdef FILTERABLE_TEXTURE_CACHE
        oColor = vec4(
            float(QuantizeRGB8ToRGB6(color.r * 255.0)),
            float(QuantizeRGB8ToRGB6(color.g * 255.0)),
            float(QuantizeRGB8ToRGB6(color.b * 255.0)),
            float(QuantizeChannel(color.a, 31.0))) / 255.0;
#else
        oColor = uvec4(
            QuantizeRGB8ToRGB6(color.r * 255.0),
            QuantizeRGB8ToRGB6(color.g * 255.0),
            QuantizeRGB8ToRGB6(color.b * 255.0),
            QuantizeChannel(color.a, 31.0));
#endif
    }
    else if (uOutputFormat == 1)
    {
#ifdef FILTERABLE_TEXTURE_CACHE
        oColor = vec4(
            float(QuantizeChannel(color.r, 255.0)),
            float(QuantizeChannel(color.g, 255.0)),
            float(QuantizeChannel(color.b, 255.0)),
            float(QuantizeChannel(color.a, 255.0))) / 255.0;
#else
        oColor = uvec4(
            QuantizeChannel(color.r, 255.0),
            QuantizeChannel(color.g, 255.0),
            QuantizeChannel(color.b, 255.0),
            QuantizeChannel(color.a, 255.0));
#endif
    }
    else
    {
#ifdef FILTERABLE_TEXTURE_CACHE
        oColor = vec4(
            float(QuantizeChannel(color.b, 255.0)),
            float(QuantizeChannel(color.g, 255.0)),
            float(QuantizeChannel(color.r, 255.0)),
            float(QuantizeChannel(color.a, 255.0))) / 255.0;
#else
        oColor = uvec4(
            QuantizeChannel(color.b, 255.0),
            QuantizeChannel(color.g, 255.0),
            QuantizeChannel(color.r, 255.0),
            QuantizeChannel(color.a, 255.0));
#endif
    }
}