flake: rewrite, use flake-parts, split flake into flake/

Author: alyraffauf

flake.lock

@@ -2,135 +2,30 @@
   description = "A Flake-native deployment tool for distributed NixOS and Darwin clusters.";
 
   inputs = {
-    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
-  };
-
-  outputs = {
-    self,
-    nixpkgs,
-  }: let
-    allSystems = [
-      "aarch64-darwin"
-      "aarch64-linux"
-      "x86_64-darwin"
-      "x86_64-linux"
-    ];
-
-    forAllSystems = f:
-      nixpkgs.lib.genAttrs allSystems (system:
-        f {
-          pkgs = import self.inputs.nixpkgs {
-            inherit system;
-          };
-        });
-  in {
-    formatter = self.inputs.nixpkgs.lib.genAttrs allSystems (system: self.packages.${system}.formatter);
-
-    packages = forAllSystems ({pkgs}: rec {
-      formatter = pkgs.writeShellApplication {
-        name = "formatter";
-
-        runtimeInputs = with pkgs; [
-          alejandra
-          diffutils
-          findutils
-          go
-          gopls
-          nodePackages.prettier
-          shfmt
-        ];
-
-        text = builtins.readFile ./utils/formatter.sh;
-      };
-
-      nynx = pkgs.buildGoModule {
-        pname = "nynx";
-        src = ./src;
-        vendorHash = null;
-
-        nativeBuildInputs = with pkgs; [
-          makeWrapper
-        ];
-
-        postInstall = ''
-          wrapProgram $out/bin/nynx \
-            --prefix PATH : ${pkgs.lib.makeBinPath [pkgs.nix-eval-jobs]}
-        '';
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
 
-        version =
-          if self ? shortRev
-          then "git-${self.shortRev}"
-          else "dev";
-      };
-
-      default = nynx;
-    });
-
-    # darwinConfigurations = {
-    #   darwintest =  self.inputs.nix-darwin.lib.darwinSystem {
-    #     system = "aarch64-darwin";
-    #     modules = [
-    #       {
-    #         networking.hostName = "darwintest";
-    #       }
-    #     ];
-    #   };
-    # };
-
-    devShells = forAllSystems ({pkgs}: {
-      default = pkgs.mkShell {
-        packages = with pkgs;
-          [
-            go
-            gopls
-            nixd
-            nodePackages.prettier
-            shfmt
-          ]
-          ++ [
-            self.packages.${pkgs.system}.formatter
-            self.packages.${pkgs.system}.nynx
-          ];
-      };
-    });
-
-    nixosConfigurations = {
-      nixostest = self.inputs.nixpkgs.lib.nixosSystem {
-        system = "x86_64-linux";
-        modules = [
-          ({...}: {
-            imports = [];
-
-            boot.loader.systemd-boot.enable = true;
-            boot.loader.efi.canTouchEfiVariables = true;
-
-            fileSystems."/" = {
-              device = "/dev/sda1";
-              fsType = "ext4";
-            };
-
-            networking.hostName = "nixostest";
-            services.openssh.enable = true;
-            users.users.root.initialPassword = "changeme";
-            system.stateVersion = "25.05";
-          })
-        ];
-      };
+    treefmt-nix = {
+      url = "github:numtide/treefmt-nix";
+      inputs.nixpkgs.follows = "nixpkgs";
     };
 
-    nynxDeployments = {
-      nixostest = {
-        hostname = "nixostest"; # Will be assumed from deployment name if not specified.
-        output = self.nixosConfigurations.nixostest.config.system.build.toplevel;
-        # type = "nixos"; # Will be inferred based on the output.
-        user = "root";
-      };
+    flake-parts.url = "github:hercules-ci/flake-parts";
+  };
 
-      # fortree = {
-      #   output = self.inputs.nixcfg.darwinConfigurations.fortree.config.system.build.toplevel;
-      #   user = "aly";
-      #   type = "darwin";
-      # };
+  outputs = inputs @ {flake-parts, ...}:
+    flake-parts.lib.mkFlake {inherit inputs;} {
+      systems = [
+        "aarch64-darwin"
+        "aarch64-linux"
+        "x86_64-darwin"
+        "x86_64-linux"
+      ];
+
+      imports = [
+        ./flake/devShells.nix
+        ./flake/packages.nix
+        ./flake/treefmt.nix
+        inputs.treefmt-nix.flakeModule
+      ];
     };
-  };
 }

flake.nix

@@ -0,0 +1,23 @@
+_: {
+  perSystem = {
+    config,
+    lib,
+    pkgs,
+    self',
+    ...
+  }: {
+    devShells.default = pkgs.mkShell {
+      packages = with pkgs;
+        [
+          go
+          gopls
+          nixd
+          nodePackages.prettier
+        ]
+        ++ lib.attrValues config.treefmt.build.programs
+        ++ [
+          self'.packages.nynx
+        ];
+    };
+  };
+}

flake/devShells.nix

@@ -0,0 +1,31 @@
+_: {
+  perSystem = {
+    pkgs,
+    self',
+    ...
+  }: {
+    packages = rec {
+      nynx = pkgs.buildGoModule {
+        pname = "nynx";
+        src = ../src;
+        vendorHash = null;
+
+        nativeBuildInputs = with pkgs; [
+          makeWrapper
+        ];
+
+        postInstall = ''
+          wrapProgram $out/bin/nynx \
+            --prefix PATH : ${pkgs.lib.makeBinPath [pkgs.nix-eval-jobs]}
+        '';
+
+        version =
+          if self' ? shortRev
+          then "git-${self'.shortRev}"
+          else "dev";
+      };
+
+      default = nynx;
+    };
+  };
+}

flake/packages.nix

@@ -0,0 +1,11 @@
+_: {
+  perSystem = _: {
+    treefmt.config.programs = {
+      alejandra.enable = true;
+      deadnix.enable = true;
+      gofmt.enable = true;
+      prettier.enable = true;
+      statix.enable = true;
+    };
+  };
+}