aiogram-template/Justfile at master · andrew000/aiogram-template · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
set shell := ["bash", "-c"]
set windows-shell := ["powershell.exe", "-NoLogo", "-Command"]

app-dir := "app"
bot-dir := "bot"

[windows]
up:
    docker compose \
      --env-file .env \
      --file docker-compose.yml \
      up \
      -d \
      --build \
      --timeout 60 \
      bot

[unix]
up:
    docker compose \
      --env-file .env \
      --file docker-compose.yml \
      build \
      --build-arg USER_ID=$(id -u) \
      --build-arg GROUP_ID=$(id -g) \
      --build-arg USER_NAME=$(whoami) \
      bot

    docker compose \
      --env-file .env \
      --file docker-compose.yml \
      up \
      -d \
      --timeout 60 \
      bot

[windows]
up-db:
    docker compose \
      --env-file .env \
      --file docker-compose.yml \
      up \
      -d \
      --build \
      --timeout 60 \
      database redis

[unix]
up-db:
    docker compose \
      --env-file .env \
      --file docker-compose.yml \
      build \
      --build-arg USER_ID=$(id -u) \
      --build-arg GROUP_ID=$(id -g) \
      --build-arg USER_NAME=$(whoami) \
      database redis

    docker compose \
      --env-file .env \
      --file docker-compose.yml \
      up \
      -d \
      --timeout 60 \
      database redis

[windows]
build:
    docker compose \
      --env-file .env \
      --file docker-compose.yml \
      build \
      bot migrations

[unix]
build:
    docker compose \
      --env-file .env \
      --file docker-compose.yml \
      build \
      --build-arg USER_ID=$(id -u) \
      --build-arg GROUP_ID=$(id -g) \
      --build-arg USER_NAME=$(whoami) \
      bot migrations

down:
    docker compose \
      --env-file .env \
      --file docker-compose.yml \
      down \
      --timeout 60

pull:
    git pull origin master
    git submodule update --init --recursive

extract-locales:
    uv run ftl extract

stub:
    uv run ftl stub
    uv run ruff check {{ app-dir }}/{{ bot-dir }}/stub.pyi --fix --unsafe-fixes
    uv run ruff format {{ app-dir }}/{{ bot-dir }}/stub.pyi
    uv run isort {{ app-dir }}/{{ bot-dir }}/stub.pyi

untranslated:
    uv run ftl untranslated

lint:
    echo "Running ruff..."
    uv run ruff check {{ app-dir }} --show-fixes --preview

format:
    echo "Running ruff check with --fix..."
    uv run ruff check {{ app-dir }} --fix --unsafe-fixes

    echo "Running ruff..."
    uv run ruff format {{ app-dir }}

    echo "Running isort..."
    uv run isort {{ app-dir }}

mypy:
    echo "Running MyPy..."
    uv run mypy \
    --explicit-package-bases \
    --num-workers 8 \
    --native-parser \
    {{ app-dir }}/{{ bot-dir }}

outdated:
    uv tree --universal --outdated --depth 2

sync:
    uv lock --upgrade
    uv sync --all-extras

create-revision message: build
    docker compose \
        --env-file .env \
        --file docker-compose.yml \
        run \
        --rm \
        migrations \
        bash -c ".venv/bin/alembic --config alembic.ini revision --autogenerate -m '{{ message }}'"

upgrade-revision revision: build
    docker compose \
        --env-file .env \
        --file docker-compose.yml \
        run \
        --rm \
        migrations \
        bash -c ".venv/bin/alembic --config alembic.ini upgrade {{ revision }}"

downgrade-revision revision: build
    docker compose \
        --env-file .env \
        --file docker-compose.yml \
        run \
        --rm \
        migrations \
        bash -c ".venv/bin/alembic --config alembic.ini downgrade {{ revision }}"

current-revision: build
    docker compose \
        --env-file .env \
        --file docker-compose.yml \
        run \
        --rm \
        migrations \
        bash -c ".venv/bin/alembic --config alembic.ini current"

create-init-revision: build
    docker compose \
        --env-file .env \
        --file docker-compose.yml \
        run \
        --rm \
        migrations \
        bash -c ".venv/bin/alembic --config alembic.ini revision --autogenerate -m 'Initial' --rev-id 000000000000"