anki/release.just at main · ankitects/anki · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
set windows-shell := ["pwsh", "-NoLogo", "-NoProfileLoadTime", "-Command"]

version := `cat .version`

# Prepare a release: validate version, check CI, update .version
[arg("version", long)]
[arg("ref", long)]
[arg("skip-ci-check", long)]
prepare version ref skip-ci-check="false":
    gh workflow run prepare-release.yml --ref {{ ref }} \
        -f version="{{ version }}" \
        -f skip-ci-check={{ skip-ci-check }}

# Build all platforms, no signing or publishing
[arg("ref", long)]
build ref:
    gh workflow run release.yml --ref {{ ref }} \
        -f version="{{ version }}" \
        -f sign=false \
        -f draft-release=false \
        -f publish-testpypi=false \
        -f publish-pypi=false

# Build and sign artifacts
[arg("ref", long)]
sign ref:
    gh workflow run release.yml --ref {{ ref }} \
        -f version="{{ version }}" \
        -f sign=true \
        -f draft-release=false \
        -f publish-testpypi=false \
        -f publish-pypi=false

# Full public release: sign, draft, testpypi, pypi
[arg("ref", long)]
public ref:
    gh workflow run release.yml --ref {{ ref }} \
        -f version="{{ version }}" \
        -f sign=true \
        -f draft-release=true \
        -f publish-testpypi=true \
        -f publish-pypi=true

# Publish Python packages to TestPyPI only
[arg("ref", long)]
testpypi ref:
    gh workflow run release.yml --ref {{ ref }} \
        -f version="{{ version }}" \
        -f sign=false \
        -f draft-release=false \
        -f publish-testpypi=true \
        -f publish-pypi=false

# Publish Python packages to TestPyPI and PyPI
[arg("ref", long)]
pypi ref:
    gh workflow run release.yml --ref {{ ref }} \
        -f version="{{ version }}" \
        -f sign=false \
        -f draft-release=false \
        -f publish-testpypi=true \
        -f publish-pypi=true

# Manual release with explicit flags
[arg("ref", long)]
[arg("sign", long)]
[arg("draft-release", long)]
[arg("publish-testpypi", long)]
[arg("publish-pypi", long)]
[arg("skip-ci-check", long)]
custom ref sign="false" draft-release="false" publish-testpypi="false" publish-pypi="false" skip-ci-check="false":
    gh workflow run release.yml --ref {{ ref }} \
        -f version="{{ version }}" \
        -f sign={{ sign }} \
        -f draft-release={{ draft-release }} \
        -f publish-testpypi={{ publish-testpypi }} \
        -f publish-pypi={{ publish-pypi }} \
        -f skip-ci-check={{ skip-ci-check }}