gradle-docker-java/build.gradle at main · augi/gradle-docker-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
plugins {
    id 'groovy'
    id 'maven-publish'
    id 'java-gradle-plugin'
    id 'org.jreleaser' version '1.22.0'
    id 'com.gradle.plugin-publish' version '1.3.1'
}

group 'cz.augi'
version = version == 'unspecified' ? 'DEVELOPER-SNAPSHOT' : version

repositories {
    mavenCentral()
}

dependencies {
    testImplementation group: 'junit', name: 'junit', version: '4.13.2'
    testImplementation ('org.spockframework:spock-core:2.3-groovy-3.0') {
        exclude group:'org.codehaus.groovy'
    }
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
}

test {
    useJUnitPlatform()
    testLogging {
        events 'failed'
        exceptionFormat 'full'
    }
}

project.ext.set('gradle.publish.key', System.getenv('GRADLE_PORTAL_KEY'))
project.ext.set('gradle.publish.secret', System.getenv('GRADLE_PORTAL_SECRET'))

gradlePlugin {
    website = 'https://github.com/augi/gradle-docker-java'
    vcsUrl = 'https://github.com/augi/gradle-docker-java'
    plugins {
        dockerJavaPlugin {
            id = 'cz.augi.docker-java'
            displayName = 'Gradle Docker Java plugin'
            description = 'Gradle plugin that wraps your JVM application to a new Docker image.'
            implementationClass = 'cz.augi.gradle.dockerjava.DockerJavaPlugin'
            tags.set(['docker', 'java', 'jvm'])
        }
    }
}

java {
    withJavadocJar()
    withSourcesJar()
}

afterEvaluate {
    publishing {
        publications.forEach {
            it.pom {
                name = 'Gradle Docker Java Plugin'
                description = 'Gradle plugin that wraps your JVM application to a new Docker image.'
                url = 'https://github.com/augi/gradle-docker-java'
                licenses {
                    license {
                        name = 'The MIT License'
                        url = 'http://www.opensource.org/licenses/mit-license.php'
                    }
                }
                developers {
                    developer {
                        id = 'augi'
                        name = 'Michal Augustýn'
                        email = 'augustyn.michal@gmail.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/augi/gradle-docker-java.git'
                    developerConnection = 'scm:git:ssh://github.com/augi/gradle-docker-java.git'
                    url = 'https://github.com/augi/gradle-docker-java'
                }
            }
        }
        repositories {
            maven {
                url = layout.buildDirectory.dir('staging-deploy')
            }
        }
    }
}

jreleaser {
    signing {
        active = 'ALWAYS'
        armored = true
        String base64Key = System.getenv('SIGNING_KEY')
        if (base64Key) {
            secretKey = new String(Base64.decoder.decode(base64Key))
        }
        String base64PublicKey = System.getenv('SIGNING_PUBLIC_KEY')
        if (base64PublicKey) {
            publicKey = new String(Base64.decoder.decode(base64PublicKey))
        }
    }
    deploy {
        maven {
            mavenCentral {
                sonatype {
                    active = 'ALWAYS'
                    url = 'https://central.sonatype.com/api/v1/publisher'
                    stagingRepository('build/staging-deploy')
                }
            }
        }
    }
    release {
        github {
            enabled = false
        }
    }
}