blocksense/nix/pkgs/default.nix at 21f6b08b3ca9931bf2947ee96327d21b48e79e30 · blocksense-network/blocksense · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
{
  inputs,
  self,
  ...
}:
{
  perSystem =
    {
      lib,
      pkgs,
      inputs',
      self',
      config,
      system,
      ...
    }:
    let
      rust = self'.legacyPackages.rustToolchain;

      craneLib = (inputs.mcl-blockchain.inputs.crane.mkLib pkgs).overrideToolchain rust;

      version = "dev";

      blocksense-rs = pkgs.callPackage ./blocksense-rs {
        inherit craneLib version;
        inherit (self.lib) filesets;
      };

      allOracleScripts = pkgs.callPackage ./oracle-script {
        inherit craneLib version;
        inherit (self.lib) filesets;
      };
      mkOracleScript =
        name:
        let
          inherit (self.lib) dashToUnderscore;
          oracleName = dashToUnderscore name;
        in
        pkgs.runCommandLocal "blocksense-oracle-${name}" { } ''
          mkdir -p $out/lib
          ln -s ${allOracleScripts}/lib/${oracleName}.wasm $out/lib/${oracleName}.wasm
        '';

      mkApp = package: exeName: {
        type = "app";
        program = "${package}/bin/${exeName}";
      };

      mkSpinStateDir = pkgs.callPackage ./spin-plugin {
        spin = lib.getExe' inputs'.nixpkgs-unstable.legacyPackages.fermyon-spin "spin";
      };

      # Blama
      blama = pkgs.callPackage ./blama { blama-src = inputs.blama.outPath; };

      # Onchain Interactions
      yarn-packages = pkgs.callPackage ./onchain-interactions {
        inherit (inputs.yarnpnp2nix.lib.${system}) mkYarnPackagesFromManifest;
      };
      onchain-interactions = yarn-packages."@blocksense/onchain-interactions@workspace:libs/ts/onchain-interactions";
    in
    {
      apps = {
        sequencer = mkApp blocksense-rs "sequencer";
        reporter = mkApp blocksense-rs "launch_reporter";
        blocksense = mkApp blocksense-rs "blocksense";
        trigger-oracle = mkApp blocksense-rs "trigger-oracle";
        blockchain_reader = mkApp pkgs.apacheKafka "kafka-console-consumer.sh";
        aggregate_consensus_reader = mkApp pkgs.apacheKafka "kafka-console-consumer.sh";
      };
      packages = {
        inherit blocksense-rs;
        inherit blama;
      };
      legacyPackages = {
        inherit yarn-packages;
        inherit onchain-interactions;

        oracle-scripts = {
          cex-price-feeds = mkOracleScript "cex-price-feeds";
          exsat-holdings = mkOracleScript "exsat-holdings";
          gecko-terminal = mkOracleScript "gecko-terminal";
          borrow-rates = mkOracleScript "borrow-rates";
          eth-rpc = mkOracleScript "eth-rpc";
          stock-price-feeds = mkOracleScript "stock-price-feeds";
          forex-price-feeds = mkOracleScript "forex-price-feeds";
          commodities-price-feeds = mkOracleScript "commodities-price-feeds";
          spout-rwa = mkOracleScript "spout-rwa";
          eth-gas-info = mkOracleScript "eth-gas-info";
        };

        spinPlugins = {
          triggerOracle = mkSpinStateDir {
            name = "trigger-oracle";
            description = "Run Blocksense oracle components at timed intervals";
            homepage = "https://github.com/blocksense-network/blocksense/tree/main/apps/trigger-oracle";
            license = "Apache-2.0";
            spinCompatibility = ">=2.2";
            version = "0.1.0";
            packages = [ self'.apps.trigger-oracle.program ];
          };
        };
      };
    };
}