gradle-maven-sync-plugin/build.gradle at master · bsideup/gradle-maven-sync-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
plugins {
    id "java-gradle-plugin"
    id "com.gradle.plugin-publish" version "0.9.7"
    id 'com.github.johnrengelman.shadow' version '1.2.3'
    id "com.github.samueltbrown.cucumber" version "0.9"
}

group = "com.github.bsideup"

sourceCompatibility = targetCompatibility = 1.8

pluginBundle {
    website = vcsUrl = 'https://github.com/bsideup/gradle-maven-sync-plugin'
    description = 'Sync your Gradle build with the dependencies from pom.xml'
    tags = ['maven', 'pom', 'pom.xml', 'sync', 'migration']

    plugins {
        syncPlugin {
            id = "com.github.bsideup.maven-sync"
            displayName = 'Gradle Greeting plugin'
        }
    }
}

gradlePlugin {
    plugins {
        syncPlugin {
            id = "com.github.bsideup.maven-sync"
            implementationClass = "com.github.bsideup.gradle.plugins.maven.sync.MavenDependenciesPlugin"
        }
    }
}

configurations {
    plugin.description = 'The compile dependencies for the plugin, excluding the local dependencies to avoid problems with Shadow'
    compile.extendsFrom plugin
}

shadowJar {
    configurations = [project.configurations.plugin]
    classifier = null
    relocate 'org.jdom2', 'com.github.bsideup.maven-sync.shaded.org.jdom2'
    relocate 'org.zeroturnaround.exec', 'com.github.bsideup.maven-sync.shaded.org.zeroturnaround.exec'

    exclude 'META-INF/LICENSE'
    exclude 'META-INF/NOTICE'
    exclude 'META-INF/maven/**/**'

    dependencies {
        include(dependency('org.jdom:.*'))
        include(dependency('org.zeroturnaround:.*'))
    }
}

jar.deleteAllActions()
jar.dependsOn shadowJar

cucumber {
    println(testReportDirName)
    formats = [
            'pretty',
            "json:${project.buildDir}/test-results/cucumber.json".toString(),
            "junit:${test.reports.junitXml.destination}/cucumber.xml".toString()
    ]
    glueDirs = ['classpath:steps']
    strict = true
}
tasks.cucumber.dependsOn(tasks.pluginUnderTestMetadata, tasks.testClasses)
test.dependsOn(tasks.cucumber)

repositories {
    jcenter()
}

dependencies {
    compileOnly 'org.projectlombok:lombok:1.16.12'

    plugin 'org.zeroturnaround:zt-exec:1.9'
    plugin 'org.jdom:jdom2:2.0.6'

    testCompileOnly 'org.projectlombok:lombok:1.16.12'

    testCompile gradleTestKit()
    testCompile 'info.cukes:cucumber-java:1.2.4'
    testCompile 'junit:junit:4.12'
    testCompile 'org.assertj:assertj-core:3.6.1'
    testCompile 'org.apache.maven:maven-model:2.2.1'
    testCompile 'org.apache.commons:commons-lang3:3.5'

    cucumberRuntime sourceSets.test.output
}