league/flake.nix at master · clonkspot/league · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
{
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  inputs.flake-utils.url = "github:numtide/flake-utils";

  inputs.league-game-events.url = "github:clonkspot/league-game-events";
  inputs.league-game-events.inputs.nixpkgs.follows = "nixpkgs";

  outputs = { self, nixpkgs, flake-utils, league-game-events }:
    (flake-utils.lib.eachDefaultSystem
      (system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        {
          packages.default = pkgs.callPackage ./. { };
          devShells.default = pkgs.mkShell {
            inputsFrom = [
              self.packages.${system}.default
            ];
          };
        })
    ) // {
      overlays.default = final: prev: {
        league = self.packages.${prev.system}.default;
        league-game-events = league-game-events.packages.${prev.system}.default;
      };
      nixosModules.default = import ./module.nix;
      # Container for testing
      nixosConfigurations.container = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          self.nixosModules.default
          ({ pkgs, ... }: {
            nixpkgs.overlays = [ self.overlays.default ];
            boot.isContainer = true;
            networking.firewall.allowedTCPPorts = [ 80 ];

            services.league = {
              enable = true;
              hostname = ":80";
              enableMysql = true;
              headerFileDE = pkgs.writeText "header.html" "";
              footerFileDE = pkgs.writeText "footer.html" "";
              headerFileEN = pkgs.writeText "header.html" "";
              footerFileEN = pkgs.writeText "footer.html" "";
              extraConf = ''
                require_once('lib/dummy_auth.class.php');
              '';
            };

          })
        ];
      };
    };
}