paper-2021-language-derivatives/SizedAutomatic.lagda at main · conal/paper-2021-language-derivatives · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
\begin{code}[hide]
{-# OPTIONS --guardedness --sized-types #-}

open import Level
open import Decidability hiding (_◂_)
open import Relation.Binary.PropositionalEquality using (_≡_) ; open _≡_

module SizedAutomatic {ℓ} {A : Set ℓ} (_≟_ : Decidable₂ {A = A} _≡_) where

open import Size
open import Data.List using ([]; _∷_)

open import Misc {ℓ}
open import Inverses {ℓ}

module ◇ where
  -- open import Language A public
  open import Predicate public ; open ListOps A public
  open import Calculus A public

open ◇ using (ν⋆; δ⋆; ν☆; δ☆; ν𝟏; δ𝟏; ν`; δ`)

private
  variable
    P Q : ◇.Lang
    s : Set ℓ
    i : Size
\end{code}

%<*api>
{\mathindent0ex
\hfill
\begin{minipage}[c]{52ex}
\begin{code}[hide]
infixr  6 _∪_
infixl  7 _∩_
infixl  7 _⋆_
infixr  7 _·_
infix   9 _◂_
infixl 10 _☆
\end{code}
\begin{code}
record Lang i (P : ◇.Lang) : Set (suc ℓ) where
  coinductive
  field
    ν : Dec (◇.ν P)
    δ : ∀ {j : Size< i} → (a : A) → Lang j (◇.δ P a)
\end{code}
\begin{code}[hide]
open Lang
\end{code}
\end{minipage}
\hfill
\begin{minipage}[c]{27ex}
\begin{code}
⟦_⟧‽ : Lang ∞ P → Decidable P
⟦ p ⟧‽     []    = ν p
⟦ p ⟧‽ (a  ∷ w)  = ⟦ δ p a ⟧‽ w
\end{code}
\end{minipage}
\hfill\;
\iftalk
\vspace{-3ex}
\fi
\begin{center}
\begin{code}
∅    : Lang i ◇.∅
𝒰    : Lang i ◇.𝒰
_∪_  : Lang i  P  → Lang i Q  → Lang i (P  ◇.∪  Q)
_∩_  : Lang i  P  → Lang i Q  → Lang i (P  ◇.∩  Q)
_·_  : Dec     s  → Lang i P  → Lang i (s  ◇.·  P)
𝟏    : Lang i ◇.𝟏
_⋆_  : Lang i  P  → Lang i Q  → Lang i (P  ◇.⋆  Q)
_☆   : Lang i  P  → Lang i (P ◇.☆)
`    : (a : A) → Lang i (◇.` a)
_◂_  : (Q ⟷ P) → Lang i P → Lang i Q
\end{code}
\end{center}
}
%</api>

%<*semantics>
\begin{code}
⟦_⟧ : Lang ∞ P → ◇.Lang
⟦_⟧ {P} _ = P
\end{code}
%</semantics>

%<*defs>
{\mathindent0ex
\setstretch{1.6}
\rules{\begin{code}
ν ∅ = ⊥‽
\end{code}
}{\begin{code}
δ ∅ a = ∅
\end{code}}

\rules{\begin{code}
ν 𝒰 = ⊤‽
\end{code}
}{\begin{code}
δ 𝒰 a = 𝒰
\end{code}}

\rules{\begin{code}
ν (p ∪ q) = ν p ⊎‽ ν q
\end{code}
}{\begin{code}
δ (p ∪ q) a = δ p a ∪ δ q a
\end{code}}

\rules{\begin{code}
ν (p ∩ q) = ν p ×‽ ν q
\end{code}
}{\begin{code}
δ (p ∩ q) a = δ p a ∩ δ q a
\end{code}}

\rules{\begin{code}
ν (s · p) = s ×‽ ν p
\end{code}
}{\begin{code}
δ (s · p) a = s · δ p a
\end{code}}

\rules{\begin{code}
ν 𝟏 = ν𝟏 ◃ ⊤‽
\end{code}
}{\begin{code}
δ 𝟏 a = δ𝟏 ◂ ∅
\end{code}}

\rules{\begin{code}
ν (p ⋆ q) = ν⋆ ◃ (ν p ×‽ ν q)
\end{code}
}{\begin{code}
δ (p ⋆ q) a = δ⋆ ◂ (ν p · δ q a ∪ δ p a ⋆ q)
\end{code}}

\rules{\begin{code}
ν (p ☆) = ν☆ ◃ (ν p ✶‽)
\end{code}
}{\begin{code}
δ (p ☆) a = δ☆ ◂ (ν p ✶‽ · (δ p a ⋆ p ☆))
\end{code}}

\rules{\begin{code}
ν (` a) = ν` ◃ ⊥‽
\end{code}
}{\begin{code}
δ (` c) a = δ` ◂ ((a ≟ c) · 𝟏)
\end{code}}

\rules{\begin{code}
ν (f ◂ p) = f ◃ ν p
\end{code}
}{\begin{code}
δ (f ◂ p) a = f ◂ δ p a
\end{code}}
}
%</defs>