fix(jreleaser): move JReleaser configuration to root build.gradle.kts

- Apply JReleaser plugin directly in root build.gradle.kts with version
- Remove JReleaser configuration from convention plugin
- This fixes the immutableRelease NullPointerException issue

Author: drallgood

build-logic/src/main/kotlin/de.brendamour.java-conventions.gradle.kts

@@ -22,76 +22,6 @@ plugins {
     jacoco
 }
 
-// Apply JReleaser plugin only to root project
-if (project == rootProject) {
-    apply(plugin = "org.jreleaser")
-    
-    // Configure JReleaser directly after applying the plugin
-    configure<org.jreleaser.gradle.plugin.JReleaserExtension> {
-        gitRootSearch.set(true)
-
-        project {
-            name.set("jpasskit")
-            description.set("Java Library for Apple PassKit Web Service")
-            website.set(JPASSKIT_WEBSITE)
-            license.set("Apache-2.0")
-            authors.set(listOf(JPASSKIT_AUTHOR))
-        }
-
-        release {
-            github {
-                repoOwner.set("drallgood")
-                name.set("jpasskit")
-                overwrite.set(true)
-                skipTag.set(true)  // We're creating the tag manually
-                changelog {
-                    preset.set("conventional-commits")
-                    skipMergeCommits.set(true)
-                }
-            }
-        }
-
-        signing {
-            active.set(Active.ALWAYS)
-            armored.set(true)
-            command {
-                executable.set("gpg")
-                args.set(listOf("--batch", "--yes", "--pinentry-mode", "loopback"))
-                keyName.set("9474B9FCBDF93BEE7CC4B69B4CE3C3B7A5E5FCC2")
-            }
-            mode.set(Signing.Mode.COMMAND)
-        }
-
-        deploy {
-            maven {
-                val projs: List<Project> = listOf(rootProject) + rootProject.subprojects.toList()
-                val stagingPaths: List<String> = projs.map { p: Project ->
-                    p.layout.buildDirectory.dir("staging-deploy").get().asFile.absolutePath
-                }
-                mavenCentral {
-                    create("release-deploy") {
-                        active.set(Active.RELEASE)
-                        url.set("https://central.sonatype.com/api/v1/publisher")
-                        stagingRepositories.set(providers.provider { stagingPaths })
-                        applyMavenCentralRules.set(true)
-                    }
-                }
-                nexus2 {
-                    create("snapshot-deploy") {
-                        active.set(Active.SNAPSHOT)
-                        url.set("https://central.sonatype.com/api/v1/publisher")
-                        snapshotUrl.set("https://central.sonatype.com/repository/maven-snapshots")
-                        stagingRepositories.set(providers.provider { stagingPaths })
-                        applyMavenCentralRules.set(true)
-                        closeRepository.set(true)
-                        snapshotSupported.set(true)
-                    }
-                }
-            }
-        }
-    }
-}
-
 jacoco {
     toolVersion = "0.8.13"
 }

build.gradle.kts

@@ -1,6 +1,75 @@
+import org.jreleaser.model.Active
+import org.jreleaser.model.Signing
+
 plugins {
     `maven-publish`
     id("de.brendamour.java-conventions")
+    id("org.jreleaser") version "1.21.0"
+}
+
+jreleaser {
+    gitRootSearch.set(true)
+
+    project {
+        name.set("jpasskit")
+        description.set("Java Library for Apple PassKit Web Service")
+        website.set("https://github.com/drallgood/jpasskit")
+        license.set("Apache-2.0")
+        authors.set(listOf("Patrice Brend'amour"))
+    }
+
+    release {
+        github {
+            repoOwner.set("drallgood")
+            name.set("jpasskit")
+            overwrite.set(true)
+            skipTag.set(true)
+            changelog {
+                preset.set("conventional-commits")
+                skipMergeCommits.set(true)
+            }
+        }
+    }
+
+    signing {
+        active.set(Active.ALWAYS)
+        armored.set(true)
+        command {
+            executable.set("gpg")
+            args.set(listOf("--batch", "--yes", "--pinentry-mode", "loopback"))
+            keyName.set("9474B9FCBDF93BEE7CC4B69B4CE3C3B7A5E5FCC2")
+        }
+        mode.set(Signing.Mode.COMMAND)
+    }
+
+    deploy {
+        maven {
+            val stagingPaths = listOf(
+                layout.buildDirectory.dir("staging-deploy").get().asFile.absolutePath,
+                project(":jpasskit").layout.buildDirectory.dir("staging-deploy").get().asFile.absolutePath,
+                project(":jpasskit.server").layout.buildDirectory.dir("staging-deploy").get().asFile.absolutePath
+            )
+            mavenCentral {
+                create("release-deploy") {
+                    active.set(Active.RELEASE)
+                    url.set("https://central.sonatype.com/api/v1/publisher")
+                    stagingRepositories.set(stagingPaths)
+                    applyMavenCentralRules.set(true)
+                }
+            }
+            nexus2 {
+                create("snapshot-deploy") {
+                    active.set(Active.SNAPSHOT)
+                    url.set("https://central.sonatype.com/api/v1/publisher")
+                    snapshotUrl.set("https://central.sonatype.com/repository/maven-snapshots")
+                    stagingRepositories.set(stagingPaths)
+                    applyMavenCentralRules.set(true)
+                    closeRepository.set(true)
+                    snapshotSupported.set(true)
+                }
+            }
+        }
+    }
 }
 
 allprojects {