nixos/justfile at master · fbosch/nixos · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
# NixOS flake task runner
# Usage: just <recipe>

# List available recipes
default:
    @just --list

# Build and switch to the current host configuration
switch:
    nh os switch

# Build without switching (dry run)
build:
    nh os test

# Build custom container images for helium
build-helium:
    sudo build-helium-images

# Build custom container images for openmemory
build-openmemory:
    sudo build-openmemory-images

# Build all custom container images
build-images: build-helium build-openmemory

# Run linter (statix, deadnix, treefmt, actionlint, shellcheck)
lint:
    nix run .#lint

# Validate documented service ports against rvn-srv declarations
check-service-ports:
    bash ./scripts/check-service-ports.sh

# Format all files
fmt:
    nix run .#fmt

# Re-encrypt all secrets with current .sops.yaml recipients
update-sops-keys:
    bash ./scripts/update-sops-keys.sh

# Update GitHub avatar hash in flake metadata
update-avatar:
    bash ./scripts/update-avatar.sh

# Update a local by-name package (optionally pass package=surge)
update-local-package package='':
    if [ -n "{{package}}" ]; then bash ./scripts/update-local-package.sh "{{package}}"; else bash ./scripts/update-local-package.sh; fi

# Rotate the encrypted GPG backup gist from the current local key
rotate-gpg-gist:
    nix run .#rotate-gpg-gist

# Show the GPG gist rotation actions without writing to GitHub
rotate-gpg-gist-dry:
    nix run .#rotate-gpg-gist -- --dry-run

# Install the pre-commit hook
install-hooks:
    mkdir -p .git/hooks
    printf '#!/usr/bin/env bash\nexec nix run .#pre-commit-wrapper "$@"\n' > .git/hooks/pre-commit
    chmod +x .git/hooks/pre-commit
    @echo "Installed pre-commit hook"