ForcePack/paper/build.gradle.kts at cca7447e5a6b824128a19d58335c7a8a24174d09 · fishwob/ForcePack · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
plugins {
    id("buildlogic.java-platform-conventions")
}

repositories {
    maven("https://erethon.de/repo/")
    maven("https://repo.convallyria.com/releases")
    maven("https://repo.convallyria.com/snapshots")
    maven("https://repo.viaversion.com")
    maven("https://repo.dmulloy2.net/repository/public/")
    maven("https://jitpack.io") {
        content {
            includeGroup("com.github.LoneDev6")
        }
    }
    maven {
        name = "grimacSnapshots"
        url = uri("https://repo.grim.ac/snapshots")
        content {
            includeGroup("com.github.retrooper")
            includeGroup("ac.grim.grimac")
            includeGroup("ac.grim.packetevents")
        }
    }
    maven("https://repo.papermc.io/repository/maven-public/")
    maven("https://repo.codemc.io/repository/maven-snapshots/")
}

configurations {
    all {
        resolutionStrategy {
            force("net.kyori:adventure-api:4.25.0")
            force("net.kyori:adventure-bom:4.25.0")
        }
    }
}

dependencies {
    implementation(project(":api"))
    implementation(project(":folia"))
    implementation(project(":webserver", "shadow"))

    compileOnly("io.papermc.paper:paper-api:1.21.11-R0.1-SNAPSHOT") {
        exclude("net.kyori") // avoid conflicts
    }
    compileOnly("com.viaversion:viaversion-api:4.9.2")
    compileOnly("io.netty:netty-all:4.1.105.Final")
    compileOnly("com.github.LoneDev6:api-itemsadder:3.6.1")

    implementation("org.incendo:cloud-paper:2.0.0-beta.15") {
        exclude("org.checkerframework")
    }
    implementation("net.kyori:adventure-platform-bukkit:4.4.1") {
        exclude("net.kyori", "adventure-api") // not up-to-date - use minimessage version
    }
    implementation("net.kyori:adventure-text-minimessage:4.25.0")
    implementation("org.bstats:bstats-bukkit:3.0.2")
    implementation("com.github.retrooper:packetevents-spigot:2.12.2+6dca3cc-SNAPSHOT")
}

tasks {
    shadowJar {
        // Avoid Paper remapping our jar, packetevents will use the correct namespace
        manifest {
            attributes["paperweight-mappings-namespace"] = "mojang"
        }

        minimize {
            exclude(project(":webserver"))
        }
        mergeServiceFiles()
        relocate("io.leangen.geantyref", "forcepack.libs.geantyref")
        relocate("net.kyori", "com.convallyria.forcepack.paper.libs.adventure")
        relocate("io.papermc.lib", "com.convallyria.forcepack.paper.libs.paperlib")
        relocate("com.convallyria.languagy", "com.convallyria.forcepack.paper.libs.languagy")
        relocate("org.bstats", "com.convallyria.forcepack.paper.libs.bstats")

//        exclude("**/assets/mappings/") // We don't need these TODO pls fix Krishna
    }

    processResources {
        filesMatching("plugin.yml") {
            expand("version" to project.version)
        }
    }
}