nixcfg/default.nix at main · gkze/nixcfg · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
{
  src ? ./.,
  inputs ? { },
  lib ? null,
  pkgsFor ? null,
}:
let
  repoSrc = src;
  nixcfgDir = src + "/lib";
  nixcfgPath = file: nixcfgDir + "/${file}";

  exports = import (nixcfgPath "exports.nix") { inherit src; };
  basePackageMaterialization = import (nixcfgPath "package-materialization.nix") {
    inherit src;
  };

  initialLib = lib;
  initialPkgsFor = pkgsFor;

  requireLib =
    candidate:
    if candidate != null then
      candidate
    else if initialLib != null then
      initialLib
    else
      throw "default.nix: pass `lib` to mkLib (typically nixpkgs.lib).";

  requirePkgsFor =
    candidate:
    if candidate != null then
      candidate
    else if initialPkgsFor != null then
      initialPkgsFor
    else
      throw "default.nix: pass `pkgsFor` to mkLib (system -> pkgs attrset).";

  resolveOutputsWithLib =
    outputsArg:
    if builtins.isAttrs outputsArg && outputsArg ? lib && outputsArg.lib != null then
      outputsArg
    else if self.lib != null then
      (if builtins.isAttrs outputsArg then outputsArg else { }) // { inherit (self) lib; }
    else
      throw "default.nix: mkPackages needs `outputsArg.lib` (or import default.nix with `lib` and `pkgsFor`).";

  mkPackageMaterialization =
    outputsArg:
    import (nixcfgPath "package-materialization.nix") {
      inherit src;
      inherit (outputsArg) lib;
      outputs = outputsArg;
    };

  mkLibImpl =
    {
      lib,
      pkgsFor,
      outputs,
    }:
    import (src + "/lib.nix") {
      inherit
        inputs
        lib
        outputs
        pkgsFor
        src
        ;
    };

  self = rec {
    inherit (exports)
      api
      apiVersion
      constructorNames
      darwinModules
      homeModules
      moduleSets
      nixosModules
      ;

    modules = moduleSets;

    inherit (basePackageMaterialization) packageNames packagePaths;

    lintFiles = import (nixcfgPath "lint-files.nix");

    mkDevShell =
      {
        lib,
        gitHooks,
        lintFiles ? self.lintFiles,
        mkNixcfgPackage ? (
          pkgs:
          pkgs.callPackage (src + "/packages/nixcfg.nix") {
            inherit inputs;
            outputs = self;
          }
        ),
        src ? repoSrc,
      }:
      import (nixcfgPath "dev-shell.nix") {
        inherit
          src
          gitHooks
          lib
          lintFiles
          mkNixcfgPackage
          ;
      };

    mkOverlay =
      {
        name ? "default",
        slib ? null,
      }:
      import (nixcfgPath "compat-overlay.nix") {
        inherit
          inputs
          name
          slib
          ;
        outputs = self;
      };

    overlays =
      (import (src + "/overlays/default.nix") {
        inherit inputs;
        outputs = self;
      })
      // {
        default = self.mkOverlay { };
      };

    mkPackages =
      {
        pkgs,
        system ? pkgs.stdenv.hostPlatform.system,
        inputsArg ? inputs,
        outputsArg ? self,
        extraPackageArgs ? { },
      }:
      let
        resolvedOutputs = resolveOutputsWithLib outputsArg;
        packageMaterialization = mkPackageMaterialization resolvedOutputs;
      in
      packageMaterialization.callPackagesForSystem {
        inherit
          extraPackageArgs
          pkgs
          system
          ;
        inputs = inputsArg;
      };

    mkLib =
      {
        lib ? null,
        pkgsFor ? null,
        ...
      }@args:
      mkLibImpl (
        {
          lib = requireLib lib;
          pkgsFor = requirePkgsFor pkgsFor;
          outputs = self;
        }
        // builtins.removeAttrs args [
          "lib"
          "pkgsFor"
        ]
      );

    lib =
      if initialLib != null && initialPkgsFor != null then
        mkLibImpl {
          lib = initialLib;
          pkgsFor = initialPkgsFor;
          outputs = self;
        }
      else
        null;

    constructors =
      if self.lib == null then
        { }
      else
        builtins.listToAttrs (
          builtins.map (name: {
            inherit name;
            value = builtins.getAttr name self.lib;
          }) self.constructorNames
        );
  };
in
self