govctl/flake.nix at main · govctl-org/govctl · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
{
  description = "govctl – Project governance CLI for RFC, ADR, and Work Item management";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        cargoToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);
      in
      {
        packages = {
          govctl = pkgs.rustPlatform.buildRustPackage {
            pname = "govctl";
            inherit (cargoToml.package) version;

            src = pkgs.lib.cleanSource ./.;

            useFetchCargoVendor = true;
            cargoLock.lockFile = ./Cargo.lock;

            meta = {
              description = "Project governance CLI for RFC, ADR, and Work Item management";
              homepage = "https://github.com/govctl-org/govctl";
              license = pkgs.lib.licenses.mit;
              mainProgram = "govctl";
            };
          };

          default = self.packages.${system}.govctl;
        };

        devShells.default = pkgs.mkShell {
          inputsFrom = [ self.packages.${system}.govctl ];
          packages = with pkgs; [
            rust-analyzer
            clippy
          ];
        };
      }
    );
}