openvas-scanner/flake.nix at b24c2eeaa1e8a38698b3789175deaaece52f6ab7 · greenbone/openvas-scanner · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
{
  description = "OpenVAS — Open Vulnerability Assessment Scanner";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    flake-parts.url = "github:hercules-ci/flake-parts";
    crane = {
      url = "github:ipetkov/crane";
    };
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{ self, flake-parts, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      perSystem =
        { system, pkgs, ... }:
        let
          rustToolchain = pkgs.fenix.fromToolchainFile {
            dir = self + /rust;
            sha256 = "sha256-gh/xTkxKHL4eiRXzWv8KP7vfjSk61Iq48x47BEDFgfk=";
          };

          craneLib = (inputs.crane.mkLib pkgs).overrideToolchain rustToolchain;
        in
        rec {
          formatter = pkgs.nixfmt;

          _module.args.pkgs = import inputs.nixpkgs {
            inherit system;
            overlays = [ inputs.fenix.overlays.default ];
          };

          packages = import ./nix/packages {
            inherit pkgs craneLib;
            src = self;
          };

          apps =
            let
              mkApp = name: {
                type = "app";
                program = "${packages.${name}}/bin/${name}";
              };
            in
            {
              openvasd = mkApp "openvasd";
              scannerctl = mkApp "scannerctl";
              feed-filter = mkApp "feed-filter";
              openvas = mkApp "openvas";
            };

          devShells.default = pkgs.mkShell {
            inputsFrom = builtins.attrValues packages;
            buildInputs = with pkgs; [
              cmake
              gcc
              pkg-config
              bison
              flex
              doxygen
              pandoc
              glib
              json-glib
              libgcrypt
              gpgme
              libpcap
              libssh
              libksba
              gnutls
              curl
              libbsd
              krb5
              file
              net-snmp
              nmap
              redis
              rustToolchain
              clang-tools
              gdb
              valgrind
            ];
          };
        };

      flake.overlays.default = final: prev: {
        inherit (self.packages.${final.system})
          gvm-libs
          openvasd
          scannerctl
          feed-filter
          scannerlib
          openvas
          ;
      };
    };
}