plugin-s3/build.gradle at main · halo-dev/plugin-s3 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
plugins {
    id 'java'
    id "io.freefair.lombok" version "9.2.0"
    id "run.halo.plugin.devtools" version "0.8.0"
}

group 'run.halo.s3os'

repositories {
    mavenCentral()
}

dependencies {
    implementation platform('run.halo.tools.platform:plugin:2.24.0')
    compileOnly 'run.halo.app:api'

    implementation platform('software.amazon.awssdk:bom:2.46.13')
    implementation('software.amazon.awssdk:s3') {
        exclude group: 'org.slf4j'
        exclude group: 'commons-logging'
    }

    testImplementation 'run.halo.app:api'
    testImplementation 'io.projectreactor:reactor-test'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

configurations.runtimeClasspath {
    exclude group: 'org.reactivestreams', module: 'reactive-streams'
}

test {
    useJUnitPlatform()
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = "UTF-8"
    options.release = 21
}

tasks.register('processUiResources', Copy) {
    from project(':console').layout.buildDirectory.dir('dist')
    into layout.buildDirectory.dir('resources/main/console')
    dependsOn project(':console').tasks.named('assemble')
    shouldRunAfter tasks.named('processResources')
}

tasks.named('classes') {
    dependsOn tasks.named('processUiResources')
}

tasks.named('generatePluginComponentsIdx') {
    notCompatibleWithConfigurationCache('This task invokes "Task.project" at execution time, which is not supported with configuration cache.')
}

halo {
    version = '2.24'
}


haloPlugin {
    openApi {
        outputDir = file("$rootDir/api-docs/openapi/v3_0")
        groupingRules {
            s3V1alpha1Api {
                displayName = 'Extension API for S3 Plugin'
                pathsToMatch = [
                    '/apis/s3os.halo.run/v1alpha1/**',
                ]
            }
        }
        groupedApiMappings = [
                '/v3/api-docs/s3V1alpha1Api': 's3V1alpha1Api.json'
        ]
        generator {
            outputDir = file("${projectDir}/console/src/api/generated")
        }
    }
}