AndroidLowLevelDetector/settings.gradle.kts at develop · imknown/AndroidLowLevelDetector · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
import org.gradle.kotlin.dsl.support.uppercaseFirstChar

pluginManagement {
    includeBuild("build-logic")

    repositories {
        google {
            content {
                includeGroupByRegex("com\\.android.*")
                includeGroupByRegex("com\\.google.*")
                includeGroupByRegex("androidx.*")
            }
        }
        mavenCentral()
        gradlePluginPortal()
    }
}

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google {
            content {
                includeGroupByRegex("com\\.android.*")
                includeGroupByRegex("com\\.google.*")
                includeGroupByRegex("androidx.*")
            }
        }
        mavenCentral()
        maven("https://jitpack.io")
    }

    versionCatalogs {
        fun String.toToml() {
            val originalName = this
            val libName = "libs${originalName.uppercaseFirstChar()}"
            register(libName) {
                from(files("gradle/toml/$originalName.toml"))
            }
        }

        "build".toToml()
        "android".toToml()
        "kotlin".toToml()
        "google".toToml()
        "thirdParty".toToml()
    }
}

rootProject.name = "AndroidLowLevelDetector"

include(":binderDetector")
include(":base")
include(":app")

// region [Build Scan]
// https://gradle.com/scans/gradle/
// https://docs.gradle.com/develocity/gradle-plugin/current/
plugins {
    // https://plugins.gradle.org/plugin/com.gradle.develocity
    id("com.gradle.develocity") version "4.4.0"

    // https://docs.gradle.org/current/userguide/gradle_daemon.html#sec:configuring_daemon_jvm
    // ./gradlew -q javaToolchains
    // ./gradlew updateDaemonJvm --jvm-version=25 --jvm-vendor=adoptium
    // https://plugins.gradle.org/plugin/org.gradle.toolchains.foojay-resolver-convention
    id("org.gradle.toolchains.foojay-resolver-convention") version "1.0.0"
}

develocity {
    buildScan {
        termsOfUseUrl = "https://gradle.com/help/legal-terms-of-use"
        termsOfUseAgree = "yes"

        publishing.onlyIf { false }
    }
}
// endregion [Build Scan]