nix-config/flake.nix at main · josqu4red/nix-config · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
{
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";
    nixos-hardware.url = "github:NixOS/nixos-hardware";
    impermanence = {
      url = "github:nix-community/impermanence";
      inputs.home-manager.follows = "home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    home-manager = {
      url = "github:nix-community/home-manager/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    disko = {
      url = "github:nix-community/disko";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    firefox-addons = {
      url = "gitlab:rycee/nur-expressions?dir=pkgs/firefox-addons";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    ssh-to-pgp = {
      url = "github:Mic92/ssh-to-pgp?rev=c175033ca42c116939a3decb2a6461b7396c9bb1";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixos-generators = {
      url = "github:nix-community/nixos-generators";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixpkgs-mongodb.url = "github:NixOS/nixpkgs/9f0c42f8bc7151b8e7e5840fb3bd454ad850d8c5";
    llm-agents = {
      url = "github:numtide/llm-agents.nix";
    };
  };

  outputs =
    { self, nixpkgs, ... }@inputs:
    let
      lib = import ./lib { inherit inputs; };
      inherit (import ./secrets/build/facts.nix { }) facts;
      inherit (lib)
        buildHomeConfigs
        buildNixosConfigs
        expandFacts
        filterSystem
        forAllSystems
        ;

      hosts = expandFacts facts;

      local-pkgs = final: _prev: import ./pkgs { pkgs = final; };

      mongodb-pin = _final: prev: {
        mongodb-7_0 =
          (import inputs.nixpkgs-mongodb {
            inherit (prev.stdenv.hostPlatform) system;
            config.allowUnfreePredicate = pkg: "mongodb" == (prev.lib.getName pkg);
          }).mongodb-7_0;
      };

      legacyPackages = forAllSystems (
        system:
        import nixpkgs {
          inherit system;
          config.allowUnfree = true;
          overlays = [
            local-pkgs
            mongodb-pin
          ];
        }
      );
    in
    {
      inherit facts legacyPackages lib;

      nixosConfigurations = buildNixosConfigs (filterSystem "linux" hosts);
      nixosModules = import ./modules/nixos;
      nixosProfiles = import ./modules/profiles;

      homeConfigurations = buildHomeConfigs hosts;
      homeModules = import ./modules/home-manager;

      devShells = forAllSystems (system: {
        default = import ./shell.nix {
          pkgs = legacyPackages.${system};
          inherit (inputs.sops-nix.packages.${system}) sops-import-keys-hook;
          inherit (inputs.ssh-to-pgp.packages.${system}) ssh-to-pgp;
        };
        fhsEnv = import ./pkgs/fhsEnv.nix { pkgs = legacyPackages.${system}; };
      });

      packages = forAllSystems (
        system:
        let
          pkgs = legacyPackages.${system};
        in
        {
          nixlive = self.nixosConfigurations.nixlive.config.system.build.isoImage;
          doc = pkgs.callPackage ./pkgs/doc.nix { };
          llma = inputs.llm-agents.packages.${system};
        }
      );
    };
}