flake.nix

{
  description = "my neovim config :3";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";

    weave = {
      url = "git+https://codeberg.org/comfysage/weave.git";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      ...
    }@inputs:
    let
      inherit (nixpkgs) lib;
      systems = lib.systems.flakeExposed;

      forAllSystems = f: lib.genAttrs systems (system: f nixpkgs.legacyPackages.${system});

      mkPackages =
        default: pkgs:
        let
          generatedPackages = import ./nix/default.nix { inherit pkgs inputs; };
          defaultPackage = lib.optionalAttrs default { default = generatedPackages.anvim; };
        in
        generatedPackages // defaultPackage;
    in
    {
      packages = forAllSystems (mkPackages true);

      homeManagerModules.default = import ./nix/hm-module.nix inputs;

      devShells = forAllSystems (pkgs: {
        default = pkgs.callPackage ./nix/shell.nix { };
      });

      formatter = forAllSystems (pkgs: pkgs.callPackage ./nix/formatter.nix { });
    };
}