Beginnings of a Utility Library

[lyxal]

I've been having a bit of fun making a utilities type library for aergia. Here's the current functions so far:

*< builtins PY

# Numerical Functions
{iota :n: ?@PY_range:0 n:}
{toBinary :n:
    = bitString @PY_bin:n:
    = digits <>
    [`@drop:bitString 2: digit
        ( == "0" digit
            +: digits 0
        ) (
            +: digits 1
        )
    ]
    ? digits
}

# List Functions
{take :lst n:
  = lst @PY_list:lst:
  = output <>
  [`@iota:n: idx
    +: output : lst idx
  ]
  ? output
}

{drop :lst n:
  # Ensure `lst` is a list
  = lst @PY_list:lst:
  [`@iota:n: idx
    ~: lst 0
  ]
  ? lst
}

# Higher-Order Functions
# Note: Aergia does not actually have function objects you can pass around
# So we're going to go with the convention that you pass in the "function" as
# a string. Like `@map:<1 2 3> "* 2 x"`. Also by convention, HOFs will use
# `x`, `y`, and `z` as argument names. Please do not be horrified at the
# (mis)usage of eval.

{map :lst fn:
  = output <>
  = fn + + "{ f :x:" fn "} @f:arg:"
  [`lst arg
    +: output ; fn
  ]
  ? output
}

{filter :lst fn:
  = output <>
  = fn + + "{ f :x:" fn "} @f:arg:"
  [`lst arg
    ( ; fn
      +: output arg
    )
  ]
    ? output
}

{reduce :lst fn:
  = acc : lst 0
  = fn + + "{ f :x y:" fn "} @f:acc curr:"
  [`@drop:lst 1: curr
    = acc ; fn
  ]
  ? acc
}

A little sample of the library in use:

+> "aerutils.aer"

= numbers <1 2 3>
= doubled @map:numbers "? * 2 x":
> doubled

= ns @iota:10:
= evens @filter:ns "? == 0 % x 2":
> evens

= sum @reduce:evens "? + x y":
> sum

= myList <1 2 3 4 5>
> @drop:myList 1:
> myList
> @drop:myList 2:
> myList

PS ...> py -m aergia "sample.aer"
[2, 4, 6]
[0, 2, 4, 6, 8]
20
[2, 3, 4, 5]
[1, 2, 3, 4, 5]
[3, 4, 5]
[1, 2, 3, 4, 5]

[las-r]

wow, this is so cool! i never expected my little hobby project to garner even just one fan so seeing somebody working on making a little library for it is surreal. this is super elegantly made and i love it.

out of curiosity, what ide are you using? the current support for ides is a bit lackluster and id love to try and make some additions that would hopefully make the development experience in aergia more fun and intuitive.

[las-r]

also, the dynamic function generation is really cool. i honestly just made the eval functionality on a whim, so it's nice to see it actually getting some use ^^

[lyxal]

In terms of IDE, I've been using a combination of Zed and Notepad. A very wide spectrum, I know :p

[las-r]

i see! zed and notepad, i don't have support for either. i'll definitely look into developing a simple zed extension and maybe a udl for notepad as well.