extensions-source/common.gradle at main · neoto/extensions-source · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
import com.android.build.gradle.tasks.PackageAndroidArtifact

apply plugin: 'com.android.application'
apply plugin: 'kotlinx-serialization'
apply plugin: 'keiyoushi.lint'

assert !ext.has("pkgNameSuffix")
assert !ext.has("libVersion")

assert extName.chars().max().asInt < 0x180 : "Extension name should be romanized"

Project theme = ext.has("themePkg") ? project(":lib-multisrc:$themePkg") : null
if (theme != null) evaluationDependsOn(theme.path)

android {
    compileSdk = AndroidConfig.compileSdk

    namespace = "eu.kanade.tachiyomi.extension"

    sourceSets {
        main {
            manifest.srcFile layout.buildDirectory.file('tempAndroidManifest.xml')
            java.directories.clear()
            java.directories.add("src")
            kotlin.directories.clear()
            kotlin.directories.add("src")
            res.directories.clear()
            res.directories.add("res")
            assets.directories.clear()
            assets.directories.add("assets")
        }
    }

    defaultConfig {
        minSdk = AndroidConfig.minSdk
        targetSdk = AndroidConfig.targetSdk
        applicationIdSuffix = project.parent.name + "." + project.name
        versionCode = theme == null ? extVersionCode : theme.baseVersionCode + overrideVersionCode
        versionName = "1.4.$versionCode"
        base {
            archivesName = "tachiyomi-$applicationIdSuffix-v$versionName"
        }
        assert extClass.startsWith(".")
        manifestPlaceholders = [
                appName : "Tachiyomi: $extName",
                extClass: extClass,
                nsfw    : project.ext.find("isNsfw") ? 1 : 0,
        ]
        String baseUrl = project.ext.find("baseUrl") ?: ""
        if (theme != null && !baseUrl.isEmpty()) {
            def split = baseUrl.split("://")
            assert split.length == 2
            def path = split[1].split("/")
            manifestPlaceholders += [
                    SOURCEHOST  : path[0],
                    SOURCESCHEME: split[0],
            ]
        }
    }

    signingConfigs {
        release {
            storeFile = rootProject.file("signingkey.jks")
            storePassword = System.getenv("KEY_STORE_PASSWORD")
            keyAlias = System.getenv("ALIAS")
            keyPassword = System.getenv("KEY_PASSWORD")
        }
    }

    buildTypes {
        release {
            signingConfig = signingConfigs.release
            minifyEnabled = false
            vcsInfo.include = false
        }
    }

    dependenciesInfo {
        includeInApk = false
    }

    buildFeatures {
        buildConfig = true
    }

    packaging {
        resources.excludes.add("kotlin-tooling-metadata.json")
    }
}

kotlin {
    compilerOptions {
        freeCompilerArgs.add("-opt-in=kotlinx.serialization.ExperimentalSerializationApi")
    }
}

dependencies {
    if (theme != null) implementation(theme) // Overrides core launcher icons
    implementation(project(":core"))
    compileOnly(libs.bundles.common)
}

tasks.register("copyManifestFile", Copy) {
    from 'AndroidManifest.xml'
    rename { 'tempAndroidManifest.xml' }
    into layout.buildDirectory
}

tasks.register("writeManifestFile") {
    dependsOn(copyManifestFile)
    doLast {
        File tempFile = android.sourceSets.getByName('main').manifest.srcFile
        if (!tempFile.exists()) {
            tempFile.parentFile.mkdirs()
            tempFile.write('<?xml version="1.0" encoding="utf-8"?>\n<manifest />\n')
        }
    }
}

afterEvaluate {
    tasks.withType(PackageAndroidArtifact).configureEach {
        // need to be in afterEvaluate to overwrite default value
        createdBy = ""
        // https://stackoverflow.com/a/77745844
        doFirst { appMetadata.asFile.getOrNull()?.write('') }
    }
}

preBuild.dependsOn(writeManifestFile)