flake.nix

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };
  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    (flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          config = {
            allowUnfreePredicate = pkg: pkg.pname == "ngrok";
          };
        };

        readmeGeneratorForHelm = pkgs.buildNpmPackage {
          pname = "readme-generator-for-helm";
          version = "2.6.1";

          src = pkgs.fetchFromGitHub {
            owner = "bitnami";
            repo = "readme-generator-for-helm";
            rev = "2.6.1";
            hash = "sha256-hgVSiYOM33MMxVlt36aEc0uBWIG/OS0l7X7ZYNESO6A=";
          };

          npmDepsHash = "sha256-baRBchp4dBruLg0DoGq7GsgqXkI/mBBDowtAljC2Ckk=";
          dontNpmBuild = true;
        };

        mkScript =
          name: text:
          let
            script = pkgs.writeShellScriptBin name text;
          in
          script;

        scripts = [
          (mkScript "devhelp" ''
            cat <<'EOF'

            Welcome to the ngrok-operator development environment!

            Please make sure you have the following environment variables set:

              NGROK_API_KEY      - Your ngrok API key
              NGROK_AUTHTOKEN    - Your ngrok authtoken

            If you are using GitHub Codespaces, a kind cluster should
            already be running. You can verify this by running:

              kind get clusters

            Common commands:
              make build          - Build the operator
              make test           - Run tests
              make lint           - Run linters
              make deploy         - Deploy to the kind cluster

            For more information, see the development documentation in

              ./docs/developer-guide/README.md

            You can also run "devhelp" at any time to see this message again.
            EOF
          '')
        ];
      in
      {
        packages.readme-generator-for-helm = readmeGeneratorForHelm;

        devShells.default = pkgs.mkShell {
          buildInputs =
            with pkgs;
            [
              bashInteractive
              go_1_26
              go-tools
              golangci-lint
              gotools
              jq
              kind
              kubebuilder
              kubectl
              kubernetes-controller-tools
              (pkgs.wrapHelm pkgs.kubernetes-helm {
                plugins = [
                  # helm-unittest 1.1.0 changed plugin.yaml from a single `command` field
                  # to `platformCommand` entries with platform-suffixed binary names, but
                  # nixpkgs builds one binary from source and installs it as plain `untt`.
                  # Patch plugin.yaml to match, mirroring the fix planned for upstream nixpkgs.
                  (pkgs.kubernetes-helmPlugins.helm-unittest.overrideAttrs (old: {
                    nativeBuildInputs = (old.nativeBuildInputs or [ ]) ++ [ pkgs.yq-go ];
                    postPatch = ''
                      yq -i 'del(.platformCommand) | del(.platformHooks) | .command = "''${HELM_PLUGIN_DIR}/untt"' plugin.yaml
                    '';
                  }))
                ];
              })
              kyverno-chainsaw
              ngrok
              nixfmt
              setup-envtest
              tilt
              yq
              readmeGeneratorForHelm
            ]
            ++ scripts;

          CGO_ENABLED = "0";
          # GitHub Codespaces sets GOROOT in /etc/environment. However, we are managing
          # go via nix, so we need to unset it to avoid conflicts. See also: https://dave.cheney.net/2013/06/14/you-dont-need-to-set-goroot-really
          GOROOT = "";

          ENVTEST_K8S_VERSION = "1.34.1";

          shellHook = ''
            export KUBEBUILDER_ASSETS="$(setup-envtest use $ENVTEST_K8S_VERSION -p path)"
            devhelp
          '';
        };
      }
    ));
}