How to add config.allowUnfreePredicate into standalone nixvim code without flake setup?

[affhp]

default.nix:

let
  nixvim = import (fetchGit {
    url = "https://github.com/nix-community/nixvim";
  });
  configuration = nixvim.lib.evalNixvim {
    extraSpecialArgs = { };

    system = builtins.currentSystem;

    modules = [
      {
        plugins.git-conflict.enable = true;
      }
    ];
  };
in
configuration.config.build.package

Error message of nix-build:

       Alternatively you can configure a predicate to allow specific packages:
         { nixpkgs.config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) [
             "git-conflict.nvim"
           ];
         }

Where should it be put at?
I guess extraSpecialArgs should be used but don't know actually how.
Thanks!

[affhp]

Got it

let
  system = builtins.currentSystem;
  nixvim = import (fetchGit {
    url = "https://github.com/nix-community/nixvim";
  });
  pkgs = import nixvim.inputs.nixpkgs {
    inherit system;
    config.allowUnfreePredicate =
      pkg:
      builtins.elem (pkgs.lib.getName pkg) [
        "git-conflict.nvim"
      ];
  };
  configuration = nixvim.lib.evalNixvim {
    extraSpecialArgs = {
      inherit pkgs;
    };
    inherit system;

    modules = [
      {
        plugins.git-conflict.enable = true;
      }
    ];
  };
in
configuration.config.build.package

[MattSturgeon]

You shouldn't need specialArgs. Instead define Nixvim's nixpkgs.config.allowUnfreePredicate option within a Nixvim module.