okta-idx-android/utils.gradle at master · okta/okta-idx-android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
def build_versions = [:]
build_versions.min_sdk = 23
build_versions.compile_sdk = 35
build_versions.target_sdk = 35
ext.build_versions = build_versions

static def addRepos(RepositoryHandler handler) {
    handler.mavenLocal()
    handler.google()
    handler.mavenCentral()
    handler.jcenter()
}

def forceVersions(ConfigurationContainer configurations) {
    configurations.configureEach {
        resolutionStrategy {
            force libs.bcprov.jdk18on
            force libs.commons.io
            force libs.jackson.databind // Vulnerability fix: OKTA-614751
            force libs.netty.common
            force libs.netty.codec.http
            force libs.netty.codec.http2
            force libs.netty.handler
            force libs.protobuf.java
            force libs.woodstox.core
        }
    }
}

def configureSpotless(Project project) {
    project.apply plugin: 'com.diffplug.spotless'

    project.spotless {
        format 'misc', {
            target '**/*.gradle', '**/*.md', '**/.gitignore', '**/*.xml', '**/*.json', '**/*.properties', '**/*.yml', '**/*.kt'
            targetExclude '.idea/*', '**/build/*', '.gradle/*'

            trimTrailingWhitespace()
            endWithNewline()
        }
    }

    project.plugins.withId('kotlin-android') {
        project.spotless {
            kotlin {
                target '**/*.kt'
                ktlint()
                licenseHeaderFile rootProject.file('licenseTemplate.txt')
            }
        }
    }
}

ext.addRepos = this.&addRepos
ext.forceVersions = this.&forceVersions
ext.configureSpotless = this.&configureSpotless