okta-mobile-kotlin/build.gradle.kts at master · okta/okta-mobile-kotlin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
import com.vanniktech.maven.publish.AndroidSingleVariantLibrary
import com.vanniktech.maven.publish.JavadocJar
import com.vanniktech.maven.publish.KotlinMultiplatform
import com.vanniktech.maven.publish.MavenPublishBaseExtension
import com.vanniktech.maven.publish.SourcesJar

buildscript {
    configurations.all {
        resolutionStrategy {
            force(libs.bcprov.jdk18on)
            force(libs.bcpkix.jdk18on)
            force(libs.bcutil.jdk18on)
        }
    }

    dependencies {
        classpath(libs.gradle.maven.publish)
        classpath(libs.bcprov.jdk18on)
        classpath(libs.bcpkix.jdk18on)
        classpath(libs.bcutil.jdk18on)
    }
}

plugins {
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.kotlin.android) apply false
    alias(libs.plugins.dokka) apply false
    alias(libs.plugins.sonarqube) apply false
    alias(libs.plugins.kover) apply false
    alias(libs.plugins.compose.compiler) apply false
    alias(libs.plugins.ksp) apply false
    alias(libs.plugins.androidx.navigation.safeargs) apply false
    // No apply-false declaration here: buildSrc's own dependency on this artifact (for
    // AndroidBcvBridgePlugin) already puts it on the classpath for every subproject.
    alias(libs.plugins.androidx.room) apply false
    alias(libs.plugins.kotlin.jvm) apply false
    alias(libs.plugins.kotlin.multiplatform) apply false
    alias(libs.plugins.android.kotlin.multiplatform.library) apply false
    alias(libs.plugins.android.lint) apply false
    alias(libs.plugins.jetbrains.compose) apply false
}

allprojects {
    configurations.all {
        resolutionStrategy {
            force(libs.jackson.databind)
            force(libs.bcprov.jdk18on)
            force(libs.commons.io)
            force(libs.netty.common)
            force(libs.netty.codec.http)
            force(libs.netty.codec.http2)
            force(libs.netty.handler)
            force(libs.netty.handler.proxy)
            force(libs.protobuf.java)
            force(libs.woodstox.core)
            force(libs.commons.lang3)
            force(libs.bcprov.jdk18on)
            force(libs.bcpkix.jdk18on)
            force(libs.bcutil.jdk18on)
        }
    }

    configurations.matching { it.name.startsWith("dokka") }.configureEach {
        resolutionStrategy.eachDependency {
            if (requested.group.startsWith("com.fasterxml.jackson")) {
                useVersion("2.15.3")
            }
        }
    }
}

tasks.register("checkLegacyAbi") {
    description = "Checks API binary compatibility across all modules."
    group = "verification"
}

gradle.projectsEvaluated {
    tasks.named("checkLegacyAbi").configure {
        subprojects.forEach { subproject ->
            // checkKotlinAbi: KGP's built-in ABI validation (auth-foundation/oauth2's jvm target).
            // androidApiCheck: binary-compat-validation, for KMP android targets KGP's validator can't see.
            // releaseApiCheck: binary-compat-validation, for Android-only modules on AGP built-in Kotlin.
            listOfNotNull(
                subproject.tasks.findByName("checkKotlinAbi"),
                subproject.tasks.findByName("androidApiCheck"),
                subproject.tasks.findByName("releaseApiCheck")
            ).forEach { dependsOn(it) }
        }
    }
}

subprojects {
    plugins.withId("com.vanniktech.maven.publish.base") {
        configure<MavenPublishBaseExtension> {
            val snapshot = project.findProperty("snapshot")?.toString()?.toBoolean() ?: false
            val automaticRelease = if (snapshot) false else project.findProperty("automaticRelease")?.toString()?.toBoolean() ?: false

            publishToMavenCentral(automaticRelease)
            if (project.hasProperty("signAllPublications")) signAllPublications()

            pom {
                name.set(pomName(project))
                description.set("Okta Mobile Kotlin")
                url.set("https://github.com/okta/okta-mobile-kotlin")
                licenses {
                    license {
                        name.set("The Apache License, Version 2.0")
                        url.set("http://www.apache.org/licenses/LICENSE-2.0.txt")
                    }
                }
                developers {
                    developer {
                        id.set("alexnachbaur-okta")
                        name.set("Alex Nachbaur")
                        email.set("alex.nachbaur@okta.com")
                    }
                    developer {
                        id.set("rajdeepnanua-okta")
                        name.set("Rajdeep Nanua")
                        email.set("rajdeep.nanua@okta.com")
                    }
                    developer {
                        id.set("FeiChen-okta")
                        name.set("Fei Chen")
                        email.set("fei.chen@okta.com")
                    }
                }
                scm {
                    connection.set("scm:git@github.com:okta/okta-mobile-kotlin.git")
                    developerConnection.set("scm:git@github.com:okta/okta-mobile-kotlin.git")
                    url.set("https://github.com/okta/okta-mobile-kotlin.git")
                }
            }
            group = "com.okta.kotlin"
            version = releaseVersion(project).let { if (snapshot) "$it-SNAPSHOT" else it }

            when {
                plugins.hasPlugin("com.android.library") -> {
                    configure(
                        AndroidSingleVariantLibrary(
                            variant = "release",
                            sourcesJar = SourcesJar.Sources(),
                            javadocJar = JavadocJar.Dokka("dokkaGenerateModuleHtml")
                        )
                    )
                }

                plugins.hasPlugin("org.jetbrains.kotlin.multiplatform") -> {
                    configure(
                        KotlinMultiplatform(
                            javadocJar = JavadocJar.Dokka("dokkaGenerateModuleHtml"),
                            sourcesJar = SourcesJar.Sources()
                        )
                    )
                }
            }
        }
    }
}