cpp-jam/CMakeLists.txt at fa02ef122c744ae9cf2b01c109b05e71e038c3cf · qdrvm/cpp-jam · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
#
# Copyright Quadrivium LLC
# All Rights Reserved
# SPDX-License-Identifier: Apache-2.0
#

cmake_minimum_required(VERSION 3.25)

option(TESTING "Build and run test suite" ON)
if (TESTING)
  list(APPEND VCPKG_MANIFEST_FEATURES test)
endif ()

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)

project(cpp-jam
    VERSION 0.0.1
    LANGUAGES CXX
)

if(DEFINED CMAKE_TOOLCHAIN_FILE AND CMAKE_TOOLCHAIN_FILE MATCHES "vcpkg")
    if(DEFINED VCPKG_TARGET_TRIPLET AND VCPKG_TARGET_TRIPLET)
        set(DETECTED_TRIPLET ${VCPKG_TARGET_TRIPLET})
        message(STATUS "Using vcpkg triplet from VCPKG_TARGET_TRIPLET: ${DETECTED_TRIPLET}")
    else()
        if(WIN32)
            if(CMAKE_SIZEOF_VOID_P EQUAL 8)
                set(DETECTED_TRIPLET "x64-windows")
            else()
                set(DETECTED_TRIPLET "x86-windows")
            endif()
        elseif(APPLE)
            if(CMAKE_SIZEOF_VOID_P EQUAL 8)
                set(DETECTED_TRIPLET "x64-osx")
            else()
                set(DETECTED_TRIPLET "arm64-osx")
            endif()
        else()
            if(CMAKE_SIZEOF_VOID_P EQUAL 8)
                set(DETECTED_TRIPLET "x64-linux")
            else()
                set(DETECTED_TRIPLET "x86-linux")
            endif()
        endif()
        message(STATUS "Auto-detected vcpkg triplet: ${DETECTED_TRIPLET}")
    endif()

    set(CMAKE_INSTALL_LIBDIR "${DETECTED_TRIPLET}/lib")
    set(CMAKE_INSTALL_INCLUDEDIR "${DETECTED_TRIPLET}/include")

    message(STATUS "CMAKE_INSTALL_LIBDIR: ${CMAKE_INSTALL_LIBDIR}")
    message(STATUS "CMAKE_INSTALL_INCLUDEDIR: ${CMAKE_INSTALL_INCLUDEDIR}")
endif()

include(GNUInstallDirs)

message(STATUS "CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
message(STATUS "Boost_DIR: ${Boost_DIR}")

find_package(Python3 REQUIRED)

find_package(PkgConfig REQUIRED)
pkg_check_modules(libb2 REQUIRED IMPORTED_TARGET GLOBAL libb2)

find_package(Boost CONFIG REQUIRED COMPONENTS algorithm outcome program_options)
find_package(fmt CONFIG REQUIRED)
find_package(yaml-cpp CONFIG REQUIRED)
find_package(qdrvm-crates CONFIG REQUIRED)
find_package(scale CONFIG REQUIRED)
find_package(soralog CONFIG REQUIRED)
find_package(Boost.DI CONFIG REQUIRED)
find_package(qtils CONFIG REQUIRED)
find_package(prometheus-cpp CONFIG REQUIRED)

add_library(headers INTERFACE)
target_include_directories(headers INTERFACE
    $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/src_>
    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
)

add_subdirectory(src)

if (TESTING)
  enable_testing()

  find_package(GTest CONFIG REQUIRED)
  set(GTEST_DEPS GTest::gtest_main)

  add_subdirectory(test-vectors)
  add_subdirectory(tests)
endif ()