rasr/CMakeLists.txt at 87400a36053d8b27c7d669f238ec30d7ef8df466 · rwth-i6/rasr · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
cmake_minimum_required(VERSION 3.22)
project(RASR)

include(cmake_resources/ConfigurationTypes.cmake)
include(cmake_resources/Modules.cmake)
include(cmake_resources/CompileOptions.cmake)

option(RASR_BUILD_CHECKS "Build check executables" OFF)

if(${MODULE_PYTHON})
    include(cmake_resources/Python.cmake)
endif()

if(${MODULE_TENSORFLOW})
    include(cmake_resources/Tensorflow.cmake)
endif()

if(${MODULE_ONNX})
    include(cmake_resources/Onnx.cmake)
endif()

if (${MODULE_TORCH})
    include(cmake_resources/Torch.cmake)
endif ()

string(TOLOWER ${CMAKE_SYSTEM_NAME} SYSTEM_NAME)
string(TOLOWER ${CMAKE_BUILD_TYPE} BUILD_TYPE)
set(ARCH_DESCRIPTION
    "${SYSTEM_NAME}-${CMAKE_HOST_SYSTEM_PROCESSOR}-${BUILD_TYPE}"
)
if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
    set_property(CACHE CMAKE_INSTALL_PREFIX PROPERTY VALUE
        "${CMAKE_CURRENT_SOURCE_DIR}/arch/${ARCH_DESCRIPTION}/"
    )
endif()

function(add_install_executable executable_name)
    install(TARGETS ${executable_name} RUNTIME DESTINATION .)
    set_target_properties(
        ${executable_name} PROPERTIES OUTPUT_NAME
                                      "${executable_name}.${ARCH_DESCRIPTION}"
    )
endfunction()

function(add_install_library library_name)
    install(TARGETS ${library_name} LIBRARY DESTINATION .)
endfunction()

function(add_rasr_check_executable executable_name)
    if(RASR_BUILD_CHECKS)
        add_executable(${executable_name} ${ARGN})
    endif()
endfunction()

function(target_link_rasr_check_libraries executable_name)
    if(RASR_BUILD_CHECKS)
        target_link_libraries(${executable_name} ${ARGN})
    endif()
endfunction()

set(SOURCE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/src/SourceVersion.cc")

add_custom_command(
    OUTPUT "${SOURCE_VERSION_FILE}"
    COMMAND
        ${CMAKE_COMMAND} "-DOUTPUT_FILE=${SOURCE_VERSION_FILE}"
        "-DSOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}" -P
        "${CMAKE_CURRENT_SOURCE_DIR}/cmake_resources/GenerateSourceVersion.cmake"
    COMMENT "Generating source version information"
    VERBATIM
)

add_custom_target(SourceVersion DEPENDS "${SOURCE_VERSION_FILE}")

add_subdirectory(src/)