[Feature Request] `eglot--progress-reporters` support?

[Icy-Thought]

Is your feature request related to a problem? Please describe.
I recently noticed the lack of support for eglot--progress-reporters and thought I should create an issue for it. The reason for this request is to allow the user to tell when to expect completions to work when typing the major-mode buffer. And in my case, this is very helpful when working with rust related code projects.

Describe the solution you'd like
Support the the progress report that Eglot supplies Emacs's default mode-line with.

Describe alternatives you've considered
I have considered switching to the Emacs built-in mode-line, but found it tedious to setup.

Additional context
What the progress report looks like outside of doom-modeline:

[Master-Hash]

If you doesn't care the style, you can restore the default one by:

(add-to-list
 'mode-line-misc-info
 `(eglot--managed-mode (" [" eglot--mode-line-format "] "))
 )

after (doom-modeline-mode 1)

and maybe (setq doom-modeline-lsp nil) to deduplicate.

I wonder why this element is absent if setting before (doom-modeline-mode 1).

[cassandracomar]

this doesn't quite work as rendering the eglot modeline format is a bit more complicated and eglot doesn't expose a function to do it. at present, you have to do the following:

(setq doom-modeline-lsp nil)
(remove-hook! '(eglot-managed-mode-hook doom-modeline-mode-hook) #'doom-modeline-override-eglot)
(add-hook! 'eglot-managed-mode-hook

           (add-to-list
            'mode-line-misc-info
            `(eglot--managed-mode
              (" ["
               (:eval
                (cl-loop for e in eglot-mode-line-format
                         for render = (format-mode-line e)
                         unless (eq render "")
                         collect (cons render
                                       (eq e 'eglot-mode-line-menu))
                         into rendered
                         finally
                         (return (cl-loop for (rspec . rest) on rendered
                                          for (r . titlep) = rspec
                                          concat r
                                          when rest concat (if titlep ":" "/")))))
               "] "))))

it's probably worth an upstream PR to expose this formatting in a function we can call directly, so setting doom-modeline-lsp to nil handles this correctly.

[DevelopmentCool2449]

Alternatively, you can override the lsp segment.

For example, i use this in my config for display a
code actions counter and some lsp information:

;; Somewhere in your (use-package eglot ...
:custom
(eglot-mode-line-format
 '(eglot-mode-line-error
   eglot-mode-line-pending-requests
   eglot-mode-line-progress
   ;; Display how many code actions are available
   (:eval
    (when
        (and (memq 'mode-line eglot-code-action-indications)
             (overlay-buffer eglot--suggestion-overlay))
      (eglot--mode-line-props
       (concat eglot-code-action-indicator
               (number-to-string
                (length
                 (overlay-get
                  eglot--suggestion-overlay
                  'eglot--actions))))
       'eglot-code-action-indicator-face
       `((mouse-1 eglot-code-actions-at-mouse
                  "execute code actions at point")))))))
:config
(doom-modeline-def-segment lsp
  "Make eglot lsp segment detailed."
  (when-let* (doom-modeline-lsp
              ((bound-and-true-p eglot--managed-mode))
              (icon doom-modeline--eglot)
              (sep (doom-modeline-spc)))
    (concat
     sep
     (doom-modeline-display-icon icon)
     (format-mode-line
      (cl-loop for e in eglot-mode-line-format
               for render = (format-mode-line e)
               unless (equal render "")
               collect (cons render
                             (eq e 'eglot-mode-line-menu))
               into rendered
               finally
               (return (cl-loop for (rspec . rest) on rendered
                                for (r . _) = rspec
                                concat "/"
                                concat r
                                ;; or:
                                ;; concat r
                                ;; when rest concat (if titlep ":" "/")
                                ))))
     sep)))

[Icy-Thought]

I might just borrow that code block! Thanks a lot for sharing your customization with us! :)