infra/flake.nix at master · sinanmohd/infra · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
{
  description = "sinan's reproducible systems";

  inputs = {
    nixpkgs.url = "github:eyJhb/nixpkgs/stalwart-webadmin-fix-wasm";

    deploy-rs = {
      url = "github:serokell/deploy-rs";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    lanzaboote = {
      url = "github:nix-community/lanzaboote/v1.1.0";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    home-manager = {
      url = "github:sinanmohd/home-manager/sway-generators";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nix-index-database = {
      url = "github:nix-community/nix-index-database";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    disko = {
      url = "github:nix-community/disko/latest";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      sops-nix,
      home-manager,
      deploy-rs,
      lanzaboote,
      nix-index-database,
      disko,
    }:
    let
      lib = nixpkgs.lib;

      nixosImports = [
        sops-nix.nixosModules.sops
        home-manager.nixosModules.home-manager
        nix-index-database.nixosModules.default
        lanzaboote.nixosModules.lanzaboote
        disko.nixosModules.disko
      ];

      makeNixosModules = moduleName: {
        imports = nixosImports ++ [
          ./nix/os/modules/${moduleName}
        ];
      };
      makeNixosConfigs =
        host: system:
        lib.nixosSystem {
          inherit system;
          modules = nixosImports ++ [
            ./nix/os/hosts/${host}
          ];
        };

      makeHomeModules = moduleName: {
        imports = [
          ./nix/home/modules/${moduleName}
        ];
      };
      makeHomeConfigs =
        host: system:
        home-manager.lib.homeManagerConfiguration {
          pkgs = nixpkgs.legacyPackages.${system};
          modules = [ ./nix/home/hosts/${host} ];
        };
    in
    {
      nixosModules = lib.genAttrs [
        "common"
        "server"
        "pc"
        "wayland"
      ] makeNixosModules;
      nixosConfigurations = lib.genAttrs [
        "cez"
        "kay"
      ] (host: makeNixosConfigs host "x86_64-linux");

      homeModules = lib.genAttrs [
        "common"
        "wayland"
        "pc"
      ] makeHomeModules;
      homeConfigurations = lib.genAttrs [
        "cez"
      ] (host: makeHomeConfigs host "x86_64-linux");

      deploy = {
        sshUser = "sinan";
        user = "root";
        remoteBuild = true;
        nodes.kay = {
          hostname = "kay";
          profilesOrder = [ "system" ];
          profiles.system = {
            path = deploy-rs.lib.x86_64-linux.activate.nixos self.nixosConfigurations.kay;
          };
        };
      };

      checks = builtins.mapAttrs (system: deployLib: deployLib.deployChecks self.deploy) deploy-rs.lib;
    };
}