Cable-Tiers/build.gradle.kts at main · starforcraft/Cable-Tiers · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
import me.modmuss50.mpp.PublishModTask

plugins {
    id("com.refinedmods.refinedarchitect.root")
    id("com.refinedmods.refinedarchitect.base")
    id("me.modmuss50.mod-publish-plugin") version "1.1.0"
}

refinedarchitect {

}

val runRequiredTests by tasks.registering {
    group = LifecycleBasePlugin.VERIFICATION_GROUP
    description = "Runs tests required before building or publishing Cable Tiers."

    dependsOn(":common:test")
}

tasks.withType<PublishModTask>().configureEach {
    dependsOn(runRequiredTests)
}

tasks.named("build") {
    dependsOn(runRequiredTests)
}

val minecraftVersion: String by project
val currentChangelog: String by project

publishMods {
    changelog = currentChangelog
    type = STABLE

    val cfOptions = curseforgeOptions {
        accessToken = providers.environmentVariable("CURSEFORGE_TOKEN")
        projectId = "454382"
        minecraftVersions.add(minecraftVersion)
    }

    val mrOptions = modrinthOptions {
        accessToken = providers.environmentVariable("MODRINTH_TOKEN")
        projectId = "UsLNxQgK"
        minecraftVersions.add(minecraftVersion)
    }

    curseforge("curseforgeFabric") {
        from(cfOptions)
        file(project(":fabric"))
        modLoaders.add("fabric")
        displayName = file.map { it.asFile.name }
        requires("refined-storage", "fabric-api")
    }

    curseforge("curseforgeNeoforge") {
        from(cfOptions)
        file(project(":neoforge"))
        modLoaders.add("neoforge")
        displayName = file.map { it.asFile.name }
        requires("refined-storage")
    }

    modrinth("modrinthFabric") {
        from(mrOptions)
        file(project(":fabric"))
        modLoaders.add("fabric")
        requires("refined-storage", "fabric-api")
    }

    modrinth("modrinthNeoforge") {
        from(mrOptions)
        file(project(":neoforge"))
        modLoaders.add("neoforge")
        requires("refined-storage")
    }
}

subprojects {
    group = "com.ultramega.cabletiers"
}