jit-db-gatekeeper/flake.nix at main · supabase/jit-db-gatekeeper · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
{
  description = "PAM module example";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachSystem [ "x86_64-linux" "aarch64-linux" "aarch64-darwin" ] (system:
      let
        pkgs = import nixpkgs { inherit system; };

        makeGatekeeper = { go ? pkgs.go }:
          let
            buildGoModule = pkgs.buildGoModule.override { inherit go; };
          in
          buildGoModule {
            pname = "jit-db-gatekeeper";
            version = "1.0.4";
            src = ./.;

            vendorHash = null;

            buildInputs = [ pkgs.pam ];

            buildPhase = ''
              runHook preBuild
              go build -buildmode=c-shared -o pam_jit_pg.so
              runHook postBuild
            '';

            checkPhase = ''
                runHook preCheck
                go test -v ./...
                runHook postCheck
            '';

            installPhase = ''
              runHook preInstall
              mkdir -p $out/lib/security
              cp pam_jit_pg.so $out/lib/security/
              runHook postInstall
            '';
          };
      in {
        packages.default = makeGatekeeper { };

        lib.makeGatekeeper = makeGatekeeper;
      });
}