.drone.jsonnet

local name = 'ntfy';
local nginx = '1.24.0';
local node = '22-bookworm';
local golang = '1.25.14';
local python = '3.12-slim-bookworm';
local playwright = 'mcr.microsoft.com/playwright:v1.48.2-jammy';
local debian = 'bookworm-slim';
local platform = '26.08.01';
local store_publisher = 'stable-346';
local distro_default = 'bookworm';
local push_faker_host = 'push.mozaws.net';
local push_faker_port = '8090';
local push_faker_tls_port = '443';
local distros = ['bookworm', 'buster'];

local platform_image(distro) =
  'syncloud/platform-' + distro + ':' + platform;

local build(arch, test_ui) = [{
  kind: 'pipeline',
  type: 'docker',
  name: arch,
  platform: {
    os: 'linux',
    arch: arch,
  },
  steps: [
    {
      name: 'nginx',
      image: 'nginx:' + nginx,
      commands: [
        './nginx/build.sh',
      ],
    },
  ] + [
    {
      name: 'nginx test ' + distro,
      image: platform_image(distro),
      commands: [
        './nginx/test.sh',
      ],
    }
    for distro in distros
  ] + [
    {
      name: 'ntfy web',
      image: 'node:' + node,
      commands: [
        './ntfy/web.sh',
      ],
    },
    {
      name: 'ntfy',
      image: 'golang:' + golang,
      commands: [
        './ntfy/build.sh $DRONE_BUILD_NUMBER',
      ],
    },
  ] + [
    {
      name: 'ntfy test ' + distro,
      image: platform_image(distro),
      commands: [
        './ntfy/test.sh',
      ],
    }
    for distro in distros
  ] + [
    {
      name: 'cli',
      image: 'golang:' + golang,
      commands: [
        './cli/build.sh',
      ],
    },
    {
      name: 'push faker',
      image: 'golang:' + golang,
      commands: [
        './push-faker/build.sh',
      ],
    },
    {
      name: 'cli test',
      image: 'golang:' + golang,
      commands: [
        './cli/test.sh',
      ],
    },
    {
      name: 'package',
      image: 'debian:' + debian,
      commands: [
        './package.sh ' + name + ' $DRONE_BUILD_NUMBER',
      ],
    },
  ] + [
    {
      name: 'test ' + distro,
      image: 'python:' + python,
      commands: [
        './test/run.sh ' + distro + ' ' + name + ' $DRONE_BUILD_NUMBER',
      ],
    }
    for distro in distros
  ] + (if test_ui then [
         {
           name: push_faker_host,
           image: 'debian:' + debian,
           detach: true,
           environment: {
             PUSH_FAKER_HOST: push_faker_host,
             PUSH_FAKER_PORT: push_faker_port,
             PUSH_FAKER_TLS_PORT: push_faker_tls_port,
             PUSH_FAKER_CERT_FILE: '/drone/src/push-faker/cert.pem',
           },
           commands: [
             './push-faker/faker',
           ],
         },
         {
           name: 'e2e',
           image: playwright,
           commands: [
             './test/e2e/run.sh e2e ' + distro_default + '.com user Password1 root Password1 ' + push_faker_host + ':' + push_faker_port,
           ],
         },
       ] else []) + [
    {
      name: 'publish',
      image: 'syncloud/store-publisher:' + store_publisher,
      environment: {
        SYNCLOUD_TOKEN: { from_secret: 'SYNCLOUD_TOKEN' },
      },
      command: ['snap', '-c', '${DRONE_BRANCH}'],
      when: {
        branch: ['master', 'stable'],
        event: ['push'],
      },
    },
    {
      name: 'artifact',
      image: 'appleboy/drone-scp:1.6.4',
      settings: {
        host: { from_secret: 'artifact_host' },
        username: 'artifact',
        key: { from_secret: 'artifact_key' },
        timeout: '2m',
        command_timeout: '2m',
        target: '/home/artifact/repo/' + name + '/${DRONE_BUILD_NUMBER}-' + arch,
        source: ['artifact/*'],
        strip_components: 1,
      },
      when: {
        status: ['failure', 'success'],
      },
    },
  ],
  trigger: {
    event: ['push'],
  },
  services: [
    {
      name: name + '.' + distro + '.com',
      image: platform_image(distro),
      privileged: true,
      entrypoint: ['/bin/sh', '-c',
                   "mkdir -p /etc/systemd/system/snapd.service.d && printf '[Service]\\nExecStartPost=/bin/sh -c \"/usr/bin/snap set system refresh.hold=2099-01-01T00:00:00Z\"\\n' > /etc/systemd/system/snapd.service.d/disable-refresh.conf && exec /sbin/init"],
      volumes: [
        { name: 'dbus', path: '/var/run/dbus' },
        { name: 'dev', path: '/dev' },
      ],
    }
    for distro in distros
  ],
  volumes: [
    { name: 'dbus', host: { path: '/var/run/dbus' } },
    { name: 'dev', host: { path: '/dev' } },
  ],
}];

build('amd64', true) +
build('arm64', false) +
build('arm', false)