fix(mqtt): avoid blocking startup on retained cleanup

Author: Bolyki György

lib/teslamate/mqtt/pubsub/vehicle_subscriber.ex

@@ -49,9 +49,17 @@ defmodule TeslaMate.Mqtt.PubSub.VehicleSubscriber do
     }
 
     :ok = call(deps.vehicles, :subscribe_to_summary, [car_id])
-    :ok = clear_retained(car_id, namespace, deps.publisher)
 
-    {:ok, %State{car_id: car_id, namespace: namespace, deps: deps}}
+    {:ok, %State{car_id: car_id, namespace: namespace, deps: deps}, {:continue, :clear_retained}}
+  end
+
+  @impl true
+  def handle_continue(
+        :clear_retained,
+        %State{car_id: car_id, namespace: namespace, deps: deps} = state
+      ) do
+    :ok = clear_retained(car_id, namespace, deps.publisher)
+    {:noreply, state}
   end
 
   @publish_if_nil ~w(charge_energy_added charger_actual_current charger_phases

test/teslamate/mqtt/pubsub/vehicle_subscriber_test.exs

@@ -5,6 +5,16 @@ defmodule TeslaMate.Mqtt.PubSub.VehicleSubscriberTest do
   alias TeslaMate.Vehicles.Vehicle.Summary
   alias TeslaMate.Locations.GeoFence
 
+  defmodule BlockingPublisher do
+    def publish(test_pid, topic, message, opts) do
+      send(test_pid, {__MODULE__, {:publish, topic, message, opts}, self()})
+
+      receive do
+        :continue -> :ok
+      end
+    end
+  end
+
   defp start_subscriber(name, car_id, namespace \\ nil, publisher_responses \\ %{}) do
     publisher_name = :"mqtt_publisher_#{name}"
     vehicles_name = :"vehicles_#{name}"
@@ -28,6 +38,34 @@ defmodule TeslaMate.Mqtt.PubSub.VehicleSubscriberTest do
     )
   end
 
+  test "starts before retained topic cleanup completes", %{test: name} do
+    vehicles_name = :"vehicles_#{name}"
+    {:ok, _pid} = start_supervised({VehiclesMock, name: vehicles_name, pid: self()})
+
+    test_pid = self()
+
+    task =
+      Task.async(fn ->
+        VehicleSubscriber.start_link(
+          car_id: 0,
+          namespace: nil,
+          deps_publisher: {BlockingPublisher, test_pid},
+          deps_vehicles: {VehiclesMock, vehicles_name}
+        )
+      end)
+
+    assert_receive {VehiclesMock, {:subscribe_to_summary, 0}}
+
+    assert_receive {BlockingPublisher,
+                    {:publish, "teslamate/cars/0/healthy", "", [retain: true, qos: 1]},
+                    subscriber_pid}
+
+    assert {:ok, {:ok, ^subscriber_pid}} = Task.yield(task, 500)
+
+    send(subscriber_pid, :continue)
+    :ok = GenServer.stop(subscriber_pid)
+  end
+
   test "publishes vehicle data", %{test: name} do
     {:ok, pid} = start_subscriber(name, 0)