union/app2/app2.nix at main · unionlabs/union · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
_: {
  perSystem =
    {
      pkgs,
      pkgsUnstable,
      ensureAtRepositoryRoot,
      gitShortRev,
      lastModified,
      lastModifiedDate,
      buildPnpmPackage,
      ...
    }:
    let
      deps = with pkgsUnstable; [
        python3
        stdenv.cc
        pkg-config
        nodePackages_latest.nodejs
        pnpm_10
        imagemagick
      ];
      PUBLIC_LOG_TOKEN = "9VE47r89qMgdbCzHbtRN8pTuQyU9cWVsZMnAwyGU";
      PUBLIC_LOG_ENDPOINT = "https://logs.union.build/app";
      PUBLIC_GIT_REV = gitShortRev;
      PUBLIC_LAST_MODIFIED_DATE = lastModifiedDate;
      PUBLIC_LAST_MODIFIED_EPOCH = lastModified;
      PUBLIC_SUPABASE_URL = "https://api.dashboard.union.build";
      DEPLOYMENTS_JSON = pkgs.lib.escapeShellArg (builtins.readFile ../deployments/deployments.json);
      PUBLIC_SUPABASE_ANON_KEY = "eyJhbGciOiJIUzI1NiIsInR5cCI6IkpXVCJ9.eyJpc3MiOiJzdXBhYmFzZSIsInJlZiI6InVvcnF6cHVyeXJnZm5lY2FkYWpvIiwicm9sZSI6ImFub24iLCJpYXQiOjE3MzQzNzM0NDAsImV4cCI6MjA0OTk0OTQ0MH0.4xkWpfMkYgBz4nqUGkZVjQNP7NxLa4filDoJRCI3yWo";
    in
    {
      packages = {
        app2 = buildPnpmPackage rec {
          packageJsonPath = ./package.json;
          extraSrcs = pkgs.lib.fileset.unions [
            ../app2
            ../effect-svelte
            ../ts-sdk
            ../ts-sdk-cosmos
            ../ts-sdk-evm
            ../ts-sdk-sui
          ];
          hash = "sha256-lAmG8o1FH/cBu5Wqqb8Dxm34cRuxKfwk1w3jRP7WGDk=";
          buildInputs = deps;
          nativeBuildInputs = buildInputs;
          pnpmWorkspaces = [
            "app2"
            "@unionlabs/effect-svelte"
            "@unionlabs/sdk"
            "@unionlabs/sdk-cosmos"
            "@unionlabs/sdk-evm"
            "@unionlabs/sdk-sui"
          ];
          buildPhase = ''
            runHook preBuild
            export PUBLIC_LOG_TOKEN="${PUBLIC_LOG_TOKEN}"
            export PUBLIC_LOG_ENDPOINT="${PUBLIC_LOG_ENDPOINT}"
            export PUBLIC_GIT_REV="${PUBLIC_GIT_REV}"
            export PUBLIC_LAST_MODIFIED_DATE="${PUBLIC_LAST_MODIFIED_DATE}"
            export PUBLIC_LAST_MODIFIED_EPOCH="${PUBLIC_LAST_MODIFIED_EPOCH}"
            export PUBLIC_SUPABASE_URL="${PUBLIC_SUPABASE_URL}"
            export PUBLIC_SUPABASE_ANON_KEY="${PUBLIC_SUPABASE_ANON_KEY}"
            export PUBLIC_DEPLOYMENTS_JSON=${DEPLOYMENTS_JSON}
            pnpm --filter=app2 --filter=effect-svelte prepare
            pnpm --filter=app2 build
            runHook postBuild
          '';
          # TODO(ehegnes): make warning diagnostics exit non-zero
          checkPhase = ''
            pnpm --filter=app2 check
          '';
          doCheck = true;
          installPhase = ''
            mkdir -p $out
            cp -r ./app2/build/* $out
          '';
          doDist = false;
        };
      };
      apps = {
        app2-dev-server = {
          type = "app";
          program = pkgs.writeShellApplication {
            name = "app-dev-server";
            runtimeInputs = deps;
            text = ''
              ${ensureAtRepositoryRoot}
              cd app2/
              export PUBLIC_LOG_TOKEN="${PUBLIC_LOG_TOKEN}"
              export PUBLIC_LOG_ENDPOINT="${PUBLIC_LOG_ENDPOINT}"
              export PUBLIC_GIT_REV="${PUBLIC_GIT_REV}"
              export PUBLIC_LAST_MODIFIED_DATE="${PUBLIC_LAST_MODIFIED_DATE}"
              export PUBLIC_LAST_MODIFIED_EPOCH="${PUBLIC_LAST_MODIFIED_EPOCH}"
              export PUBLIC_SUPABASE_URL="${PUBLIC_SUPABASE_URL}"
              export PUBLIC_SUPABASE_ANON_KEY="${PUBLIC_SUPABASE_ANON_KEY}"
              export PUBLIC_DEPLOYMENTS_JSON=${DEPLOYMENTS_JSON}
              pnpm install
              pnpm run dev --host
            '';
          };
        };
        app2-check-watch = {
          type = "app";
          program = pkgs.writeShellApplication {
            name = "app-check-watch";
            runtimeInputs = deps;
            # TODO: decrease threshold to "warning"
            text = ''
              ${ensureAtRepositoryRoot}
              cd app2/
              export PUBLIC_LOG_TOKEN="${PUBLIC_LOG_TOKEN}"
              export PUBLIC_LOG_ENDPOINT="${PUBLIC_LOG_ENDPOINT}"
              export PUBLIC_GIT_REV="${PUBLIC_GIT_REV}"
              export PUBLIC_LAST_MODIFIED_DATE="${PUBLIC_LAST_MODIFIED_DATE}"
              export PUBLIC_LAST_MODIFIED_EPOCH="${PUBLIC_LAST_MODIFIED_EPOCH}"
              export PUBLIC_SUPABASE_URL="${PUBLIC_SUPABASE_URL}"
              export PUBLIC_SUPABASE_ANON_KEY="${PUBLIC_SUPABASE_ANON_KEY}"
              export PUBLIC_DEPLOYMENTS_JSON=${DEPLOYMENTS_JSON}
              pnpm run check --watch --threshold error
            '';
          };
        };
        app2-grafana = {
          type = "app";
          program = pkgs.writeShellApplication {
            name = "app-grafana";
            meta.description = "Spawn Grafana server for local app telemetry debugging";
            runtimeInputs = with pkgs; [ docker ];
            text = ''
              docker run --rm -it \
                -p 3001:3000 \
                -p 4317:4317 \
                -p 4318:4318 \
                --name grafana-otel-lgtm \
                grafana/otel-lgtm
            '';
          };
        };
        app2-sync-logo = {
          type = "app";
          program = pkgs.writeShellApplication {
            name = "app-sync-logo";
            runtimeInputs = with pkgs; [
              inkscape
            ];
            text = ''
              ${ensureAtRepositoryRoot}
              for s in 192 512; do
                inkscape site/public/u.svg -w $s -h $s -o app2/static/web-app-manifest-"$s"x"$s".png
              done
            '';
          };
        };
        app2-fetch-schema = {
          type = "app";
          program = pkgs.writeShellApplication {
            name = "app2-fetch-schema";
            runtimeInputs = deps;
            text = ''
              ${ensureAtRepositoryRoot}
              cd app2/
              pnpm dlx gql.tada generate-schema --tsconfig ./tsconfig.json --output "./src/generated/schema.graphql" "https://development.graphql.union.build/v1/graphql"
              pnpm dlx gql.tada generate-output --disable-preprocessing --tsconfig ./tsconfig.json --output ./src/generated/graphql-env.d.ts
            '';
          };
        };
      };
    };
}