nix-dotfiles/flake.nix at main · vimwtf/nix-dotfiles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
{
  description = "A Very Flakey Home Manager";

  # Initial layout shamelessly stolen from:
  # - https://github.com/Misterio77/nix-starter-configs/
  # - https://github.com/Misterio77/nix-config/

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    # You can access packages and modules from different nixpkgs revs
    # at the same time. Here's a working example:
    nixpkgs-stable.url = "github:nixos/nixpkgs/nixos-25.05";
    # Also see the 'stable-packages' overlay at 'overlays/default.nix'.

    # Home manager
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Hardware
    hardware.url = "github:nixos/nixos-hardware";

    # NixGL
    nixgl = {
      url = "github:nix-community/nixGL";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Catppuccin theme
    catppuccin.url = "github:catppuccin/nix";

    # Sops encryption
    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Zen browser
    zen-browser = {
      url = "github:0xc000022070/zen-browser-flake";
      inputs.nixpkgs.follows = "nixpkgs";
    };

  };

  outputs =
    {
      self,
      nixpkgs,
      home-manager,
      ...
    }@inputs:
    let
      inherit (self) outputs;
      lib = nixpkgs.lib // home-manager.lib;
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];
      forEachSystem = f: lib.genAttrs systems (sys: f pkgsFor.${sys});
      pkgsFor = nixpkgs.legacyPackages;

      getHostModule =
        hostname:
        let
          hostPath = ./home/hosts + "/${hostname}.nix";
          genericPath = ./home/hosts/generic.nix;
        in
        if builtins.pathExists hostPath then hostPath else genericPath;

      mkHomeConfiguration =
        {
          system,
          hostname,
          isWork ? false,
          isNixOs ? false,
        }:
        lib.homeManagerConfiguration {
          modules = [
            (getHostModule hostname)
            {
              _module.args = { inherit hostname isWork isNixOs; };
            }
          ];
          pkgs = pkgsFor.${system};
          extraSpecialArgs = { inherit inputs outputs; };
        };
    in
    {
      inherit lib;
      nixosModules = import ./modules/nixos;
      homeManagerModules = import ./modules/home-manager;

      overlays = import ./overlays { inherit inputs outputs; };

      packages = forEachSystem (pkgs: import ./pkgs { inherit pkgs; });
      devShells = forEachSystem (pkgs: {
        default = import ./shell.nix { inherit pkgs; };
      });
      formatter = forEachSystem (pkgs: pkgs.nixpkgs-fmt);

      nixosConfigurations = {
        pixnix = lib.nixosSystem {
          modules = [ ./nixos/pixnix ];
          specialArgs = { inherit inputs outputs; };
        };
        framenix = lib.nixosSystem {
          modules = [ ./nixos/framenix ];
          specialArgs = { inherit inputs outputs; };
        };
      };

      # Standalone home-manager configuration entrypoint
      # Available through 'home-manager --flake .#your-username@your-hostname'
      homeConfigurations = {
        "john@pixnix" = mkHomeConfiguration {
          hostname = "pixnix";
          system = "x86_64-linux";
          isNixOs = true;
        };
        "john@doc" = mkHomeConfiguration {
          hostname = "doc";
          system = "x86_64-linux";
        };
        "john@wsl" = mkHomeConfiguration {
          hostname = "wsl";
          isWork = true;
          system = "x86_64-linux";
        };
        "john@hezzy" = mkHomeConfiguration {
          hostname = "hezzy";
          system = "x86_64-linux";
        };
        "john@files" = mkHomeConfiguration {
          hostname = "files";
          system = "x86_64-linux";
        };
        "john@salt" = mkHomeConfiguration {
          hostname = "salt";
          system = "x86_64-linux";
        };
        "john@ubudesk" = mkHomeConfiguration {
          hostname = "ubudesk";
          system = "x86_64-linux";
        };
        "john@pocket" = mkHomeConfiguration {
          hostname = "pocket";
          system = "aarch64-linux";
        };
        "john@framenix" = mkHomeConfiguration {
          hostname = "framenix";
          system = "x86_64-linux";
          isNixOs = true;
        };
	"john@bluefin" = mkHomeConfiguration {
	  hostname = "bluefin";
	  system = "x86_64-linux";
	};
	"john@blueframe" = mkHomeConfiguration {
	  hostname = "bluefin";
	  system = "x86_64-linux";
	};
      };
    };
}