add meson build system

meson.build

@@ -0,0 +1,21 @@
+project('libltc', 'c',
+        version : '1.3.1',
+        license : 'LGPL3')
+
+cc = meson.get_compiler('c')
+m_dep = cc.find_library('m', required : false)
+
+inc = include_directories('src')
+
+subdir('src')
+
+if get_option('tests')
+  subdir('tests')
+endif
+
+pkg_mod = import('pkgconfig')
+pkg_mod.generate(libraries : ltc_lib,
+                 version : meson.project_version(),
+                 name : 'libltc',
+                 filebase : 'ltc',
+                 description : 'linear/longitudinal timecode library')

meson_options.txt

@@ -0,0 +1 @@
+option('tests', type : 'boolean', value : false, description : 'Build tests')

src/meson.build

@@ -0,0 +1,15 @@
+install_headers('ltc.h')
+
+ltc_src = files([
+  'decoder.c',
+  'encoder.c',
+  'ltc.c',
+  'timecode.c'
+])
+
+ltc_lib = library('ltc',
+                  ltc_src,
+                  include_directories : inc,
+                  dependencies : m_dep,
+                  version : '11.1.0',
+                  install : true)

tests/meson.build

@@ -0,0 +1,18 @@
+ltcencode_exe = executable('ltcencode',
+                           'ltcencode.c',
+                           include_directories : inc,
+                           link_with : ltc_lib)
+
+ltcdecode_exe = executable('ltcdecode',
+                           'ltcdecode.c',
+                           include_directories : inc,
+                           link_with : ltc_lib)
+
+test_sh = find_program('test.sh')
+
+test('All tests',
+     test_sh,
+     env: ['BLD=' + meson.current_build_dir(),
+           'SRC=' + meson.current_source_dir(),
+           'PRJ=' + meson.project_name(),
+           'VER=' + meson.project_version()])

tests/test.sh

@@ -0,0 +1,17 @@
+#!/bin/sh
+
+set -e
+
+date
+uname -a
+echo "-----------------------------------------------------------------"
+"$BLD/ltcencode" "$BLD/output.raw"
+"$BLD/ltcdecode" "$BLD/output.raw" | diff -q "$SRC/expect_48k_2sec.txt" -
+echo "-----------------------------------------------------------------"
+"$BLD/ltcencode" "$BLD/output.raw" 192000
+"$BLD/ltcdecode" "$BLD/output.raw" 7680 | diff -q "$SRC/expect_96k_2sec.txt" -
+echo "-----------------------------------------------------------------"
+"$BLD/ltcdecode" "$SRC/timecode.raw" 882 | diff -q "$SRC/timecode.txt" -
+echo "-----------------------------------------------------------------"
+echo "  $PRJ-$VER passed all tests."
+echo "-----------------------------------------------------------------"